// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  Nov 25 1998
// 
//  Description:
//      This procedure creates the help menu items.
//
//	Arguments:
//		$object - is the name of the panel or window.
//		$menuParent - is the parent window.
//

global proc doHelpMenuItems (string $object, string $menuParent) 
{
	global string $gMainHelpMenu;
	global int $gPatchNotesExistState = 0;	// 0 = not searched, 1 = found, 2 = does not exist

	int $numOfMenuItemsBefore;
	int $numOfMenuItemsAfter;
	string $menuName;
	
	// get the name of the help menu
	if ($menuParent == "MayaWindow") {
		$menuName = "MainHelpMenu";
	}else {
		$menuName = "HelpMenu";
	}

	if ($menuParent == "MayaWindow") {
		menuItem -divider true -dividerLabel (uiRes("m_doHelpMenuItems.kHelpFind"));
	}
	
	// Search Menus
	//
	menuItem -rtc "OpenMenuFinder"
		-enableCommandRepeat false;
			
	// Autodesk Help...
	//
	menuItem 
		-enableCommandRepeat false
		-rtc "Help";

	// What's New
	//
	menuItem -label (uiRes("m_doHelpMenuItems.kWhatsNew")) -subMenu true;			

		menuItem -rtc "ShowWhatsNew"
			-enableCommandRepeat false;

        string $repoName = substring(""+about("-f"),1,4);
		menuItem
			-rtc "HighlightWhatsNew"
			-version $repoName -checkBox `whatsNewHighlight -q -highlightOn`
			highlightWhatsNewHelpMenuItem;

			menuItem -optionBox true
				-annotation (uiRes("m_doHelpMenuItems.kWhatsNewPrefsAnn"))
				-c "PreferencesWindow";

		setParent -menu ..;

	// Only add to the main window
	//
	if ($menuParent == "MayaWindow") {
		menuItem -divider true -dividerLabel (uiRes("m_doHelpMenuItems.kHelpLearn")); 

		menuItem 
			-rtc "OpenStartupMovies"
			-enableCommandRepeat false;	

		// Learning Channel
		//
		menuItem 
			-rtc "OpenLearningChannel"
			-enableCommandRepeat false;

		// Tutorials
		//
        $label = (uiRes("m_doHelpMenuItems.kHelpTutorials"));
		menuItem -label $label -sm true;

		menuItem -rtc "OpenTutorials"
			-enableCommandRepeat false;			

		menuItem -rtc "OpenTrialTutorials"
			-enableCommandRepeat false;
		setParent -m ..;

		menuItem -divider true -dividerLabel (uiRes("m_doHelpMenuItems.kHelpAdvance"));

		// Learning Path
		//
		menuItem -rtc "OpenLearningPath"
			-enableCommandRepeat false;

		// Scripting Reference submenu
		//
        $label = (uiRes("m_doHelpMenuItems.kAdditionalHelp"));
		menuItem -label $label -sm true;

			menuItem -rtc "OpenMelCmdRef"
					-enableCommandRepeat false;

			if (`exists python`) {
				menuItem -rtc "OpenPyCmdRef"
					-enableCommandRepeat false;
			}

			menuItem -rtc "OpenNodeAttrRef"
				-enableCommandRepeat false;

			setParent -m ..;
		
		// Communities sub menu
		//
		$label =  (uiRes("m_doHelpMenuItems.kMayaCommunities"));
		menuItem -label $label -subMenu true;
			// AREA Community
			//
			menuItem 
				-rtc "OpenAREACommunity"
				-enableCommandRepeat false;

			// AREA Discussion Forum
			//
			menuItem 
				-rtc "OpenAREAForums"
				-enableCommandRepeat false;

			// Facebook
			//
			menuItem 
				-rtc "OpenFacebook"
				-enableCommandRepeat false;
			setParent -menu ..;
		
	// Maya Resources and Tools submenu
	//
	menuItem -label (uiRes("m_doHelpMenuItems.kMayaResourcesAndTools")) -subMenu true;
		menuItem 
			-rtc "OpenBrowserSetupAssistant"
			-enableCommandRepeat false;

		menuItem 
			-rtc "DownloadBonusTools"
			-enableCommandRepeat false;

		setParent -menu ..;

		menuItem -divider true -dividerLabel (uiRes("m_doHelpMenuItems.kHelpContribute"));
		
		// Services and Support sub menu
		//
		menuItem -label (uiRes("m_doHelpMenuItems.kServicesAndSupport")) -subMenu true;

			// Autodesk Account
			//
			menuItem 
				-rtc "OpenAutodeskAccount"
				-version 2016
				-enableCommandRepeat false;

			$troubleshootLocation = `getenv MAYA_LOCATION`;
			if(`about -mac`) {
				$troubleshootLocation += "/../../";
			} else {
				$troubleshootLocation += "/";
			}
			$troubleshootLocation += "patch_notes.html";

			if ($gPatchNotesExistState == 0) {
				$gPatchNotesExistState = 2;	// does not exist
				if (`filetest -r $troubleshootLocation`) {
					$gPatchNotesExistState = 1;	// found
				}
			}

			if ($gPatchNotesExistState == 1) {
				menuItem 
					-label (uiRes("m_doHelpMenuItems.kPatchReleaseNotes"))
					-annotation (uiRes("m_doHelpMenuItems.kPatchReleaseNotesAnn"))
					-enableCommandRepeat false
					-command ("showHelp -absolute (\"file://" + $troubleshootLocation + "\") ");
			}

			// Release Notes Updates
			//
			menuItem 
				-rtc "OpenReleaseNotes"
				-enableCommandRepeat false;
						
			// Support Center
			//
			menuItem 
				-rtc "OpenSupportCenter"
				-enableCommandRepeat false;			

			setParent -menu ..;

			// Speak Back sub menu
			//
			menuItem -version 2019 -label (uiRes("m_doHelpMenuItems.kSpeakBack")) -sm true;
				// Report a Problem...
				//
				menuItem 
					-rtc "OpenBugReport"
					-enableCommandRepeat false;

				// Ideas...
				//
				menuItem 
					-rtc "OpenFeatureRequest"
					-enableCommandRepeat false;
				
				// Join Product Research...
				//
				menuItem -version 2019
					-rtc "OpenProductResearch"
					-enableCommandRepeat false;
				
				menuItem 
					-rtc "OpenDesktopAnalytics"
					-enableCommandRepeat false;
				setParent -m ..;

		// We only need the divider if the following menu items are defined.
		menuItem -divider true -dividerLabel (uiRes("m_doHelpMenuItems.kHelpExpand"));

		menuItem -version 2014 
			-rtc "OpenAutodeskExchange"
			-enableCommandRepeat false;

		menuItem 
			-label (uiRes("m_doHelpMenuItems.kOnlineStore"))
			-image (languageResourcePath("menuIconHelp.png"))
			-enableCommandRepeat false
			-subMenu true;

		menuItem 
			-rtc "OpenAutodeskStore"
			-enableCommandRepeat false;

		menuItem -divider true;

		menuItem -version 2017 
			-rtc "OpenFBXReview"
			-enableCommandRepeat false;

		menuItem -version 2017 
			-rtc "OpenCharacterGenerator"
			-enableCommandRepeat false;
	
		menuItem -version 2017 
			-rtc "OpenTinkercad"
			-enableCommandRepeat false;

		setParent -menu ..;
	} // if ($menuParent == "MayaWindow")
	else 
	{
		menuItem -divider true; 
	}
	//	Context sensitive menu Items relative to each window.
	//
	$numOfMenuItemsBefore = `menu -query -numberOfItems $menuName`;
	doContextHelpProc $object $menuParent;
	$numOfMenuItemsAfter = `menu -query -numberOfItems $menuName`;

	if ($numOfMenuItemsBefore != $numOfMenuItemsAfter)
	{
		menuItem -divider true; 
	}

	// This section has been shifted into Additional Help submenu for the main window
	//
	if( $menuParent != "MayaWindow" ) {
		menuItem 
			-rtc "OpenMelCmdRef"
			-enableCommandRepeat false;


		if (`exists python`) {
			menuItem 
				-rtc "OpenPyCmdRef"
				-enableCommandRepeat false;
		}

		menuItem 
			-rtc "OpenNodeAttrRef"
			-enableCommandRepeat false;

		menuItem -divider true;
	}
	
	// Only add to the main window
	if (!`about -mac` && ($menuParent == "MayaWindow")) {
		menuItem -divider true -dividerLabel (uiRes("m_doHelpMenuItems.kHelpAbout"));
		
		// About
		//
		$label = (uiRes("m_doHelpMenuItems.kAboutMaya"));
		$annotation = (uiRes("m_doHelpMenuItems.kAboutMayaAnn"));
					
		menuItem 
			-rtc "ProductInformation"
			-enableCommandRepeat false;
	}

	// Home Page
	//
	menuItem 
		-rtc "OpenHomePage"
		-enableCommandRepeat false;
}

global proc updateHelpMenuItems(string $menuParent)
{
	// Update main window help items
	//
	if ($menuParent == "MayaWindow") {
		menuItem -e -checkBox `whatsNewHighlight -q -highlightOn` highlightWhatsNewHelpMenuItem;
	}
}