// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//  Creation Date:  2002 
//
//  Description:
//		Option box for paint effects to nurbs 
//

//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
//  Note:
//     Commented out Type option for this rev
//
proc setOptionVars(int $forceFactorySettings)
{
	//	HideStrokes
	//	
	if ($forceFactorySettings ||
		!`optionVar -exists pfxToNurbsHideStrokes`) {
		optionVar -intValue pfxToNurbsHideStrokes 1;
	}
}


//
//  Procedure Name:
//      paintEffectsToNurbsSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//	forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc paintEffectsToNurbsSetup(string $parent, int $forceFactorySettings)
{
    int $method;

	//	Retrieve the option settings
	//
    setOptionVars($forceFactorySettings);

	setParent $parent;

	//	Query the optionVar's and set the values into the controls.

	// Hide Strokes
	//
	int $hideStrokes = `optionVar -query pfxToNurbsHideStrokes`;
	checkBoxGrp -edit -v1 $hideStrokes pfxToNurbsHideStrokesBox;

}

//
//  Procedure Name:
//      paintEffectsToNurbsCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//	doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc paintEffectsToNurbsCallback(string $parent, int $doIt)
{
    setParent $parent;

	//	Set the optionVar's from the control values, and then
	//	perform the command.

	//	Hide Strokes
	//
	optionVar -intValue pfxToNurbsHideStrokes
		`checkBoxGrp -q -v1 pfxToNurbsHideStrokesBox`;

	if ($doIt) {
		performPaintEffectsToNurbs 0; 
		addToRecentCommandQueue "performPaintEffectsToNurbs 0" "PaintEffectsToNurbs";
	}
}

//
//  Procedure Name:
//      paintEffectsToNurbsOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc paintEffectsToNurbsOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "paintEffectsToNurbs";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	//	STEP 1:  Get the option box.
	//	============================
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	STEP 2:  Pass the command name to the option box.
	//	=================================================
	//
	setOptionBoxCommandName($commandName);
	
	//	STEP 3:  Activate the default UI template.
	//	==========================================
	//
	setUITemplate -pushTemplate DefaultTemplate;

	//	STEP 4: Create option box contents.
	//	===================================
	//	
	
	//	Turn on the wait cursor.
	//
	waitCursor -state 1;

	tabLayout -tabsVisible 0 -scrollable 1;
	
	string $parent = `columnLayout -adjustableColumn 1`;
	
	checkBoxGrp -label (uiRes("m_performPaintEffectsToNurbs.kHideStrokes")) -l1 ""
		pfxToNurbsHideStrokesBox;

	//	Turn off the wait cursor.
	//
	waitCursor -state 0;
	
	//	Step 5: Deactivate the default UI template.
	//	===========================================
	//
	setUITemplate -popTemplate;

	//	Step 6: Customize the buttons.  
	//	==============================
	//

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit -label (uiRes("m_performPaintEffectsToNurbs.kConvert"))
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	//	Step 7: Set the option box title.
	//	=================================
	//
	setOptionBoxTitle (uiRes("m_performPaintEffectsToNurbs.kConvertPaintEffectsToNURBSOptions"));

	//	Step 8: Customize the 'Help' menu item text.
	//	============================================
	//
	setOptionBoxHelpTag( "PaintEffectsToNurbs" );

	//	Step 9: Set the current values of the option box.
	//	=================================================
	//
	eval (($setup + " " + $parent + " " + 0));	
	
	//	Step 10: Show the option box.
	//	=============================
	//
	showOptionBox();
}

//
//  Procedure Name:
//      paintEffectsToNurbsHelp
//
//  Description:
//		Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string paintEffectsToNurbsHelp()
{
	return 
	"  Command: PaintEffectsToNurbs- turn paint effects strokes into nurbs.\n" +
	"Selection: Paint Effects strokes.";
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
	setOptionVars(false);

	int $hideStrokes = `optionVar -query pfxToNurbsHideStrokes`;

   	string $cmd = ("doPaintEffectsToNurbs( "+$hideStrokes+")");
	return $cmd;
}

//
//  Procedure Name:
//      performPaintEffectsToNurbs
//
//  Description:
//		Perform the performPaintEffectsToNurbs command using the corresponding 
//		option values.  This procedure will also show the option box
//		window if necessary as well as construct the command string
//		that will invoke the performPaintEffectsToNurbs command with the current
//		option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performPaintEffectsToNurbs(int $action)
{
	string $cmd = "";
	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Get the command.
			//
			$cmd = `assembleCmd`;

			//	Execute the command with the option settings.
			//
			// TODO change this to eval and have doPaintEffectsToNurbs call
			// a second routine with evalEcho, so that this command is echoed
			// when returned (case 2 below )
			evalEcho($cmd);

			break;

		//	Show the option box.
		//
		case 1:
			paintEffectsToNurbsOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}