// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  March 1999
//
//  Description:
//
//  Option box for the makePressureCurve command 
//

//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
	//	NumCvs.
	//
	if ($forceFactorySettings || !`optionVar -exists makePressureCurveNumCvs`) {
		optionVar -intValue makePressureCurveNumCvs 8;
	}

	//	Scale.
	//
	if ($forceFactorySettings || !`optionVar -exists makePressureCurveScale`) {
		optionVar -floatValue makePressureCurveScale 1.0;
	}
}

//
//  Procedure Name:
//      makePressureCurveSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//	forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc makePressureCurveSetup(string $parent, int $forceFactorySettings)
{
	//	Retrieve the option settings
	//
	setOptionVars($forceFactorySettings);

	setParent $parent;

	//	Query the optionVar's and set the values into the controls.

	//	StartFrame.
	//
	intSliderGrp -edit 
		-v `optionVar -query makePressureCurveNumCvs`
		makePressureCurveNumCvs;

	//	Stiffness.
	//
	floatSliderGrp -edit 
		-v `optionVar -query makePressureCurveScale`
		makePressureCurveScale;

}

//
//  Procedure Name:
//      makePressureCurveCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//	doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc makePressureCurveCallback(string $parent, int $doIt)
{
    setParent $parent;

	//	Set the optionVar's from the control values, and then
	//	perform the command.

	//	NumCvs.
	//
	optionVar -intValue makePressureCurveNumCvs
		`intSliderGrp -query -v makePressureCurveNumCvs`;

	//	Scale.
	//
	optionVar -floatValue makePressureCurveScale
		`floatSliderGrp -query -v makePressureCurveScale`;

	if ($doIt) {
		performMakePressureCurve 0;
	}
}

//
//  Procedure Name:
//      makePressureCurveOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc makePressureCurveOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "makePressureCurve";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	string $layout = getOptionBox();
	setParent $layout;
	
	setOptionBoxCommandName($commandName);
	
	setUITemplate -pushTemplate DefaultTemplate;

	waitCursor -state 1;

	tabLayout -tabsVisible 0 -scrollable 1;
	
	string $parent = `columnLayout -adjustableColumn 1`;
	
    intSliderGrp
        -label (uiRes("m_performMakePressureCurve.kControlPoints"))
		-field 1
		-min 2 
		-max 50 
		makePressureCurveNumCvs;

    floatSliderGrp
        -label (uiRes("m_performMakePressureCurve.kOffsetScale"))
		-field 1
		-min 0 
		-max 10 
		-pre 4
		makePressureCurveScale;

	waitCursor -state 0;
	
	setUITemplate -popTemplate;

	//	'Create' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-label (uiRes("m_performMakePressureCurve.kCreate"))
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	setOptionBoxTitle (uiRes("m_performMakePressureCurve.kMakePressureCurveOpt"));

	//	Customize the 'Help' menu item text.
	//
	setOptionBoxHelpTag( "MakePressureCurve" );

	eval (($setup + " " + $parent + " " + 0));	

	showOptionBox();
}

//
//  Procedure Name:
//      makePressureCurveHelp
//
//  Description:
//		Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string makePressureCurveHelp()
{
	return 
	"  Command: makePressureCurve - Create a curve to adjust brushstroke pressure values\n" +
	"Selection: strokes";
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
	string $cmd = "makePressureCurve";

	setOptionVars(false);

	$cmd = ($cmd
		+ " " + `optionVar -query makePressureCurveNumCvs` 
		+ " " + `optionVar -query makePressureCurveScale` 
		);

	return $cmd;
}

//
//  Procedure Name:
//      performMakePressureCurve
//
//  Description:
//		Perform the makePressureCurve command using the corresponding 
//		option values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performMakePressureCurve(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			$cmd = `assembleCmd`;
			eval($cmd);
			break;

		//	Show the option box.
		//
		case 1:
			makePressureCurveOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}