// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
global proc xformManipulatorValues(string $toolName) {
	string $parent = (`toolPropertyWindow -q -location` + "|xformManipulator");
	setParent $parent;

	// Initialize settings
	//

	int $space = `optionVar -q xformManipWorldSpace`;
	switch ($space)
	{
		case 0:
			radioButtonGrp -e -sl 1 xformManipSpaceRadio;
			optionVar -iv xformManipWorldSpace 0;
			 //$manipMode = 0 - Local space;
		break;
		case 1:
			radioButtonGrp -e -sl 2  xformManipSpaceRadio;
			optionVar -iv xformManipWorldSpace 1;
			 //$manipMode = 2 - World space;
		break;
	}

	radioButtonGrp -e
		-nrb 2
		-on1 ("optionVar -iv xformManipWorldSpace 0; setXformManip -ws 0")
		-on2 ("optionVar -iv xformManipWorldSpace 1; setXformManip -ws 1")
		-select ($space + 1)
		xformManipSpaceRadio;

	int $useRotatePivot = `optionVar -q xformManipUseRotatePivot`;
	switch ($useRotatePivot)
	{
		case 0:
			radioButtonGrp -e -sl 1 xformManipPivotRadio;
			optionVar -iv xformManipUseRotatePivot 0;
			 //$manipMode = 0 - Do not use rotate pivot;
		break;
		case 1:
			radioButtonGrp -e -sl 2  xformManipPivotRadio;
			optionVar -iv xformManipUseRotatePivot 1;
			 //$manipMode = 2 - Use rotate pivot;
		break;
	}

	radioButtonGrp -e
		-nrb 2
		-on1 ("optionVar -iv xformManipUseRotatePivot 0; setXformManip -urp 0")
		-on2 ("optionVar -iv xformManipUseRotatePivot 1; setXformManip -urp 1")
		-select ($useRotatePivot + 1)
		xformManipPivotRadio;

	string $helpTag = "xformManip";
	toolPropertySetCommon $toolName "globalManip.png" $helpTag;

	// Override Reset button command
	string $reset = `toolPropertyWindow -query -resetButton`;
	button -edit 
		-command ("optionVar -iv xformManipWorldSpace 0; setXformManip -ws 0; optionVar -iv xformManipUseRotatePivot 0; setXformManip -urp 0") 
		$reset;
	toolPropertySelect "xformManipulator";
}

global proc xformManipulatorProperties() {
	string $parent = `toolPropertyWindow -q -location`;

	setUITemplate -pushTemplate OptionsTemplate;

	setParent $parent;

	columnLayout xformManipulator;
		frameLayout -collapsable true -collapse false
			-label (uiRes("m_xformManipulatorProperties.kUniversalManipulatorSettings")) ;
			columnLayout;

				radioButtonGrp -nrb 2 
					-label (uiRes("m_xformManipulatorProperties.kTransformSpace"))  
					-label1 (uiRes("m_xformManipulatorProperties.kLocal")) 
					-label2 (uiRes("m_xformManipulatorProperties.kWorld")) 
					xformManipSpaceRadio;

				radioButtonGrp -nrb 2 
					-label (uiRes("m_xformManipulatorProperties.kRotateAround"))  
					-label1 (uiRes("m_xformManipulatorProperties.kCenter")) 
					-label2 (uiRes("m_xformManipulatorProperties.kPivot")) 
					xformManipPivotRadio;

			setParent ..;
		setParent ..;
	setParent ..;	

	setUITemplate -popTemplate;
}