// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Description:
//		This script sets the values for the specified smudge
//	context within the tool property sheet. 
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//



global proc texMoveShellMaskButtonCB( string $parent, string $context )
{
	setParent $parent; 
	int $mask = `checkBoxGrp -query -value1 textureMoveShellMaskButton`;
	texMoveUVShellContext -edit -m $mask $context;

	if ( $mask) { 
		floatSliderGrp -edit -en true textureMoveShellSpacing; 
		intSliderGrp -edit -en true textureMoveIteration;
	} else { 
		floatSliderGrp -edit -en false textureMoveShellSpacing;
		intSliderGrp -edit -en false textureMoveIteration;		
	}	
	
}

global proc texMoveShellSpacingCB( string $parent, string $context )
{
	setParent $parent;
	float $spacing = `floatSliderGrp -query -value textureMoveShellSpacing`;
	texMoveUVShellContext -edit -sb $spacing $context;
}


global proc texMoveIterationCB( string $parent, string $context )
{
	setParent $parent;
	int $iter = `intSliderGrp -query -value textureMoveIteration`;
	texMoveUVShellContext -edit -it $iter $context;
}


global proc texMoveUVShellValues( string $context ) 
{
	string $parent = `toolPropertyWindow -query -location`;
	setParent $parent;
	
	int $mask = `texMoveUVShellContext -query -m $context`;
	float $spacing = `texMoveUVShellContext -query -sb $context`;	
	int $iter = `texMoveUVShellContext -query -it $context`;
	
	checkBoxGrp -edit 
		-changeCommand ("texMoveShellMaskButtonCB " + $parent + " " + $context)
		-value1  $mask textureMoveShellMaskButton; 

	floatSliderGrp -edit 
		-changeCommand ("texMoveShellSpacingCB " + $parent + " " + $context)
		-enable $mask
		-value $spacing 
		textureMoveShellSpacing; 
		
	intSliderGrp -edit	
		-changeCommand ("texMoveIterationCB " + $parent + " " + $context)
		-enable $mask
		-value  $iter 
		textureMoveIteration; 		

	string $helpTag = "texMoveUVShellTool";
	toolPropertySetCommon $context "moveUVShellLarge.png" $helpTag; 
	toolPropertySelect "texMoveUVShell";
}