// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  26 Jun 1996
//
//  Description:
//      This procedure sets the state of the component pick mask.
//
//  Input Arguments:
//		The flag for the pick mask setting to turn on/off,
//		and the state to set that pick mask setting to.
//
//  Return Value:
//		None
//

global proc setComponentPickMask( string $maskType, int $state ) {

	//
	// Set values, based on the $state of the pick mask
	// type and $state passed to the procedure
	//
	switch ($maskType) {
        case "All":
            selectType -allComponents $state;
            // 
            // Change the $state of all the object
            // selection mask buttons in the infoBar
            //
            iconTextCheckBox -e -v $state compSelPointBtn;
            iconTextCheckBox -e -v $state compSelParmPointBtn;
            iconTextCheckBox -e -v $state compSelLineBtn;
            iconTextCheckBox -e -v $state compSelFaceBtn;
            iconTextCheckBox -e -v $state compSelHullBtn;
            iconTextCheckBox -e -v $state compSelPivotBtn;
            iconTextCheckBox -e -v $state compSelHandleBtn;
            break;
		case "Point":
			selectType
				-cv $state
				-polymeshVertex $state
				-subdivMeshPoint $state
				-latticePoint $state
				-particle $state;
			break;
		case "ParmPoint":
			selectType
				-editPoint $state
				-curveParameterPoint $state
				-surfaceParameterPoint $state
				-smu $state
				-puv $state
				-surfaceUV $state;
			break;
		case "Line":
			selectType
				-isoparm $state
				-surfaceEdge $state
				-polymeshEdge $state
				-subdivMeshEdge $state
				-springComponent $state;
			break;
		case "Facet":
			selectType
				-surfaceFace $state
				-subdivMeshFace $state
				-facet $state;
			break;
		case "Hull":
			selectType
				-hull $state;
			break;
		case "Pivot":
			selectType
				-rotatePivot $state
				-scalePivot $state
				-jointPivot $state;
			break;
		case "Marker":
			selectType
				-selectHandle $state;
			break;
		case "Other":
			selectType
				-imagePlane $state
				-localRotationAxis $state;
			break;
	}
}