// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  Thu Aug  7 21:44:35 MDT 1997
//
//  Description:
//              helps to create the controls for polyMergeEdge
//              and polyMergeFacet tools property sheet.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//

global proc polyMergeProperties (string $type, string $ctxCmd)
{
	// Global template variables for form spacing
	global int $gToolOptionBoxTemplateDescriptionMarginWidth;
	global int $gToolOptionBoxTemplateFrameSpacing;
	
	string $parent = `toolPropertyWindow -q -location`;

	setUITemplate -pushTemplate ToolOptionBoxTemplate;
	setParent $parent;

	string $title;
	if ($type == "polyMergeFacet") {
		$title = (uiRes("m_polyMergeProperties.kMergeHoleSettings"));
	} else {
		$title = (uiRes("m_polyMergeProperties.kMergeEdgeSettings"));
	}

	// Form layout
	$parent = `formLayout $type`;
	
		// Description frame
		string $descriptionFrame = 
		`frameLayout -label (uiRes("m_polyMergeProperties.kDescriptionFrame")) -mw $gToolOptionBoxTemplateDescriptionMarginWidth`;	

			if ($type == "polyMergeFacet")
			{
				text -label (uiRes("m_polyMergeProperties.kPolyMergeFaceToolDescApp")) polyMergeToolLabel;
			}
			else
			{
				text -label (uiRes("m_polyMergeProperties.kPolyMergeEdgeToolDescApp")) polyMergeToolLabel;
			}
			
		setParent $parent;

		// Settings frame
		string $settingsFrame = 
		`frameLayout -label (uiRes("m_polyMergeProperties.kSettingsFrame"))`;

			columnLayout;
			
				if ($type == "polyMergeFacet")
				{
					optionMenuGrp  -label (uiRes("m_polyMergeProperties.kMergeMode")) mergeFacetMode;
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModeFir"));
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModeMid"));
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModeSec"));
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModepFir"));
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModepMid"));
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModepSec"));
						menuItem -label (uiRes("m_polyMergeProperties.kPolyMergeFaceModeNone"));
					setParent -m ..;
				}
				else
				{
					radioButtonGrp -label (uiRes("m_polyMergeProperties.kPolyMergeEdgeModeL")) -numberOfRadioButtons 3
						-label1 (uiRes("m_polyMergeProperties.kPolyMergeEdgeModeL1"))
						-label2 (uiRes("m_polyMergeProperties.kPolyMergeEdgeModeL2"))
						-label3 (uiRes("m_polyMergeProperties.kPolyMergeEdgeModeL3"))
						-vr mergeModeRadio;
				}

			setParent ..; // columnLayout

		setParent $parent; // frameLayout
		
	setParent ..; // formLayout

	// Attach Description/Settings frames to form layout
	formLayout -e
		-af $descriptionFrame "top" $gToolOptionBoxTemplateFrameSpacing
		-af $descriptionFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $descriptionFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $descriptionFrame "bottom"

		-ac $settingsFrame "top" $gToolOptionBoxTemplateFrameSpacing $descriptionFrame
		-af $settingsFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $settingsFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $settingsFrame "bottom" 

	$parent;
	
	setUITemplate -popTemplate;
}