// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  18 April 1997
//
//  Description:
//      volumeLight default options box.  The content for each tab 
//		is not created until it is accessed for the first time.
//
//////////////////////////////////////////////////////////////////////
//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
	//	Intensity.
	//
	if ($forceFactorySettings || !`optionVar -exists volumeLightIntensity`) {
		optionVar -floatValue volumeLightIntensity 1;
	}

	//	Color.
	//
	if ($forceFactorySettings || !`optionVar -exists volumeLightColor`) {
		optionVar -floatValue volumeLightColor 1
			-floatValueAppend volumeLightColor 1
			-floatValueAppend volumeLightColor 1;
	}

	//	Exclusive.
	//
// 	if ($forceFactorySettings || !`optionVar -exists volumeLightExclusive`) {
// 		optionVar -intValue volumeLightExclusive false;
// 	}

	//	Shadows.
	//
	if ($forceFactorySettings || !`optionVar -exists volumeLightShadows`) {
		optionVar -intValue volumeLightShadows false;
	}

	//	Shadow Color.
	//
	if ($forceFactorySettings || !`optionVar -exists volumeLightShadowColor`) {
		optionVar -floatValue volumeLightShadowColor 0
			-floatValueAppend volumeLightShadowColor 0
			-floatValueAppend volumeLightShadowColor 0;
	}

// 	//	Depth Map Filter Size.
// 	//
// 	if ($forceFactorySettings || !`optionVar -exists volumeLightDepthMapFilterSize`) {
// 		optionVar -intValue volumeLightDepthMapFilterSize 1;
// 	}

// 	//	Depth Map Resolution.
// 	//
// 	if ($forceFactorySettings || !`optionVar -exists volumeLightDepthMapResolution`) {
// 		optionVar -intValue volumeLightDepthMapResolution 512;
// 	}

// 	//	Depth Map Bias.
// 	//
// 	if ($forceFactorySettings || !`optionVar -exists volumeLightDepthMapBias`) {
// 		optionVar -floatValue volumeLightDepthMapBias 0.001;
// 	}

// 	//	Vol Shadow Samples.
// 	//
// 	if ($forceFactorySettings || !`optionVar -exists volumeLightVolShadowSamples`) {
// 		optionVar -intValue volumeLightVolShadowSamples 1;
// 	}
}

//
//  Procedure Name:
//      volumeLightSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//		forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc volumeLightSetup(string $parent, int $forceFactorySettings)
{
	//	Retrieve the option settings
	//
	setOptionVars($forceFactorySettings);

	setParent $parent;
	float $rgb[3];
	
	//	Query the optionVar's and set the values into the controls.

	//	Intensity.
	//
	if (`floatSliderGrp -exists volumeLightIntensity`) {
		floatSliderGrp -edit 
			-value `optionVar -query volumeLightIntensity`
			volumeLightIntensity;
	}

	//	Color.
	//
	if (`colorSliderGrp -exists volumeLightColor`) {
		float $rgb[3] = `optionVar -query volumeLightColor`;
		colorSliderGrp -edit 
			-rgb $rgb[0] $rgb[1] $rgb[2]
			volumeLightColor;
	}

// 	//	Exclusive.
// 	//
// 	if (`checkBoxGrp -exists volumeLightExclusive`) {
// 		checkBoxGrp -edit 
// 			-value1 `optionVar -query volumeLightExclusive`
// 			volumeLightExclusive;
// 	}
	
	//	Shadows.
	//
	if (`checkBoxGrp -exists volumeLightShadows`) {
		checkBoxGrp -edit
			-value1 `optionVar -query volumeLightShadows` 
			volumeLightShadows;
	}

	//	Shadow Color.
	//
	if (`colorSliderGrp -exists volumeLightShadowColor`) {
		$rgb = `optionVar -query volumeLightShadowColor`;
		colorSliderGrp -edit 
			-rgb $rgb[0] $rgb[1] $rgb[2]
			volumeLightShadowColor;
	}

// 	//	Depth Map Filter Size.
// 	//
// 	if (`intSliderGrp -exists volumeLightDepthMapFilterSize`) {
// 		intSliderGrp -edit 
// 			-value `optionVar -query volumeLightDepthMapFilterSize`
// 			volumeLightDepthMapFilterSize;
// 	}

// 	//	Depth Map Resolution.
// 	//
// 	if (`intSliderGrp -exists volumeLightDepthMapResolution`) {
// 		intSliderGrp -edit 
// 			-value `optionVar -query volumeLightDepthMapResolution`
// 			volumeLightDepthMapResolution;
// 	}

// 	//	Depth Map Bias.
// 	//
// 	if (`intSliderGrp -exists volumeLightDepthMapBias`) {
// 		intSliderGrp -edit 
// 			-value `optionVar -query volumeLightDepthMapBias`
// 			volumeLightDepthMapBias;
// 	}

// 	//	Vol Shadow Samples.
// 	//
// 	if (`intSliderGrp -exists volumeLightVolShadowSamples`) {
// 		intSliderGrp -edit 
// 			-value `optionVar -query volumeLightVolShadowSamples`
// 			volumeLightVolShadowSamples;
// 	}
}

//
//  Procedure Name:
//      volumeLightCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//		doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc volumeLightCallback(string $parent, int $doIt)
{
    setParent $parent;
	float $rgb[3];
	
	//	Set the optionVar's from the control values, and then
	//	perform the command.

	//	Intensity.
	//
	if (`floatSliderGrp -exists volumeLightIntensity`) {
		optionVar -floatValue volumeLightIntensity		
			`floatSliderGrp -query -value volumeLightIntensity`;
	}

	//	Color.
	//
	if (`colorSliderGrp -exists volumeLightColor`) {
		$rgb = `colorSliderGrp -query -rgb volumeLightColor`;
		optionVar -floatValue volumeLightColor $rgb[0];
		optionVar -floatValueAppend volumeLightColor $rgb[1];
		optionVar -floatValueAppend volumeLightColor $rgb[2];
	}

// 	//	Exclusive.
// 	//
// 	if (`checkBoxGrp -exists volumeLightExclusive`) {
// 		optionVar -intValue volumeLightExclusive 
// 			`checkBoxGrp -query -value1 volumeLightExclusive`;
// 	}
	
	//	Shadow.
	//
	if (`checkBoxGrp -exists volumeLightShadows`) {
		optionVar -intValue volumeLightShadows
			`checkBoxGrp -query -value1 volumeLightShadows`;
	}

	//	Shadow Color.
	//
	if (`colorSliderGrp -exists volumeLightShadowColor`) {
		$rgb = `colorSliderGrp -query -rgb volumeLightShadowColor`;
		optionVar -floatValue volumeLightShadowColor $rgb[0];
		optionVar -floatValueAppend volumeLightShadowColor $rgb[1];
		optionVar -floatValueAppend volumeLightShadowColor $rgb[2];
	}

// 	//	Depth Map Filter Size.
// 	//
// 	if (`intSliderGrp -exists volumeLightDepthMapFilterSize`) {
// 		optionVar -intValue volumeLightDepthMapFilterSize
// 			`intSliderGrp -query -value volumeLightDepthMapFilterSize`;
// 	}

// 	//	Depth Map Resolution.
// 	//
// 	if (`intSliderGrp -exists volumeLightDepthMapResolution`) {
// 		optionVar -intValue volumeLightDepthMapResolution
// 			`intSliderGrp -query -value volumeLightDepthMapResolution`;
// 	}

// 	//	Depth Map Bias.
// 	//
// 	if (`floatSliderGrp -exists volumeLightBias`) {
// 		optionVar -floatValue volumeLightBias
// 			`floatSliderGrp -query -value volumeLightBias`;
// 	}

// 	//	Vol Shadow Samples.
// 	//
// 	if (`intSliderGrp -exists volumeLightVolShadowSamples`) {
// 		optionVar -intValue volumeLightVolShadowSamples 
// 			`intSliderGrp -query -value volumeLightVolShadowSamples`;
// 	}

	if ($doIt) {
		performVolumeLight 0; 
		addToRecentCommandQueue "performVolumeLight 0" "VolumeLight";
	}
}

//
//  Procedure Name:
//      createVolumeLightTabUI
//
//  Description:
//		Create the tab UI.  The contents of each tab are created only 
//		when it is required, ie. if the tab is initially visible or 
//		if the tab is selected by the user.
//
//  Input Arguments:
//      The name of the tab layout.
//
//  Return Value:
//      None.
//
global proc createVolumeLightTabUI(string $tabLayout)
{
	string $tab[] = `tabLayout -query -childArray $tabLayout`;
	int $currentTabIndex = `tabLayout -query -selectTabIndex $tabLayout`;

	//	Determine if the UI for this tab has been created yet.
	//	This is accomplished by querying the number of children
	//	in the current tab.  If the tab has no children then the UI
	//	must be created.
	//
	if (0 == `columnLayout -query -numberOfChildren $tab[$currentTabIndex-1]`) {

		setParent $tab[$currentTabIndex-1];

		string $label;
		int $index;

		//	Activate the default UI template so that the layout of this 
		//	option box is consistent with the layout of the rest of the 
		//	application.
		//
		setUITemplate -pushTemplate DefaultTemplate;

		//	Turn on the wait cursor.
		//
		waitCursor -state 1;

		//	The current tab has no children.  Determine which tab is
		//	active and create its UI.
		//
		//	RECOMMENDATION:  Use the 'Grp' commands where possible because
		//	they obey the formatting specified in the default template.
		//	This will result in a more consistent look throughout the
		//	application.
		//	
		if (1 == $currentTabIndex) {
			
    		//	Create UI for the first tab.
    		//
    		floatSliderGrp -label (uiRes("m_performVolumeLight.kIntensity"))  -fieldMaxValue 100
    			volumeLightIntensity;
	    
    		colorSliderGrp -label (uiRes("m_performVolumeLight.kColor")) 
    			volumeLightColor;
	    		
// 	    		checkBoxGrp -ncb 1 -label1 "Exclusive"
// 	    			volumeLightExclusive;
	    
			separator;

   			//	Create UI for the third tab.
   			//
  			checkBoxGrp -ncb 1 -label1 (uiRes("m_performVolumeLight.kCastShadows")) 
				volumeLightShadows;
    
			colorSliderGrp -label (uiRes("m_performVolumeLight.kShadowColor")) 
				volumeLightShadowColor;
	    		
			setParent ..;
		}

		//	Update the control values to match the options.
		//
		eval (("volumeLightSetup " + $tabLayout + " " + 0));	
	
		//	Turn off the wait cursor.
		//
		waitCursor -state 0;
		
		//	Deactivate the default UI template.
		//
		setUITemplate -popTemplate;
	}
}

//
//  Procedure Name:
//      volumeLightOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
// ********* Change 'volumeLight' in this proc to be the name of your command
proc volumeLightOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "volumeLight";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	//	STEP 1:  Get the option box.
	//	============================
	//
	//  The value returned is the name of the layout to be used as
	//	the parent for the option box UI.
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	STEP 2:  Pass the command name to the option box.
	//	=================================================
	//
	//	Any default option box behaviour based on the command name is set 
	//	up with this call.  For example, updating the 'Help' menu item with
	//	the name of the command.
	//
	setOptionBoxCommandName($commandName);

	//	STEP 3:  Activate the default UI template.
	//	==========================================
	//
	//	Activate the default UI template so that the layout of this 
	//	option box is consistent with the layout of the rest of the 
	//	application.
	//
	//	Note: this option box example delays the creation of the UI
	//	until it is required.  Therefore this step is moved to the
	//	procedure where the UI is actually created. 
	//
	//setUITemplate -pushTemplate DefaultTemplate;

	//	STEP 4: Create option box contents.
	//	===================================
	//	
	//	This, of course, will vary from option box to option box.	
	
	//	Demonstrate the delaying of UI creation via tab layouts.
	//	Instead of creating all of the option box UI initially, only
	//	create that which is initially visible.  Wait, until the 
	//	other tabs are selected to create the remaining UI.
	//
	string $tabLayout = `tabLayout -scrollable 1`;

	//	Attach an action that will be invoked before a tab is selected.
	//	
	tabLayout -edit 
		-tabsVisible false
		-preSelectCommand ("createVolumeLightTabUI " + $tabLayout)
		$tabLayout;

	//	Create just the immediate children of the tab layout so that
	//	the tabs appear.
	//
	columnLayout -adj true;
		setParent ..;
	
	//	Set the tab labels.
	//
	tabLayout -edit
		$tabLayout;

	//	Create the UI for the tab that is initially visible.
	//
	createVolumeLightTabUI($tabLayout);

	//	Step 5: Deactivate the default UI template.
	//  ===========================================
	//
	//	Note: this option box example delays the creation of the UI
	//	until it is required.  Therefore this step is moved to the
	//	procedure where the UI is actually created.
	//
	//	See also Step 2. 
	//
	//setUITemplate -popTemplate;

	//	Step 6: Customize the buttons.  
	//	==============================
	//
	//	Provide more descriptive labels for the buttons.  This is not 
	//	necessary, but in some cases, for example, a button labelled 
	//	'Create' may be more meaningful to the user than one labelled
	//	'Apply'.
	//
	//  Disable those buttons that are not applicable to the option box.
	//
	//	Attach actions to those buttons that are applicable to the option
	//	box.  Note that the 'Close' button has a default action attached 
	//	to it that will hide the window.  If a a custom action is
	//	attached to the 'Close' button then be sure to call the 'hide the
	//	option box' procedure within the custom action so that the option
	//	box is hidden properly.

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-label (uiRes("m_performVolumeLight.kCreate")) 
		-command ($callback + " " + $tabLayout + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $tabLayout + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $tabLayout + " " + 1)
		$resetBtn;

	//	Step 7: Set the option box title.
	//	=================================
	//
	setOptionBoxTitle (uiRes("m_performVolumeLight.kCreateVolumeLightOptions"));

	//	Step 8: Customize the 'Help' menu item text.
	//	============================================
	//
	setOptionBoxHelpTag( "VolumeLight" );

	//	Step 9: Set the current values of the option box.
	//	=================================================
	//
	//	NOTE:  Cannot do this here since we do not know what UI is
	//	currently visible.  This is moved to where the UI is created.
	//
	//eval (($setup + " " + $tabLayout + " " + 0));	
	
	//	Step 10: Show the option box.
	//	=============================
	//
	showOptionBox();
}

//
//  Procedure Name:
//      optionBoxExample1Help
//
//  Description:
//		Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string volumeLightHelp()
{
	return 
	"  Command: volumeLight - creates a volumeLight\n" +
	"Selection: None.";	
}

proc string getCmd()
{
	string $cmd = "defaultVolumeLight(";

	$cmd = $cmd + `optionVar -query volumeLightIntensity`;
	float $rgb[3] = `optionVar -query volumeLightColor`;
	$cmd = $cmd + ", " + $rgb[0] + "," + $rgb[1] + "," + $rgb[2];
	$cmd = $cmd + ", 0";
	$cmd = $cmd + ", " + `optionVar -query volumeLightShadows`;
	$rgb = `optionVar -query volumeLightShadowColor`;
	$cmd = $cmd + ", " + $rgb[0] + "," + $rgb[1] + "," + $rgb[2];
	$cmd = $cmd + ", 1";
	$cmd = $cmd + ");";

	return $cmd;
}

//
//  Procedure Name:
//      performVolumeLight
//
//  Description:
//		Perform the volumeLight command using the corresponding 
//		option values.  This procedure will also show the option box
//		window if necessary as well as construct the command string
//		that will invoke the volumeLight command with the current
//		option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
//  Return Value:
//      None.
//
global proc string performVolumeLight(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Retrieve the option settings
			//
			setOptionVars(false);

			//	Get the command.
			//
			$cmd = getCmd();

			//	Execute the command with the option settings.
			//
			evalEcho($cmd);

			break;

		//	Show the option box.
		//
		case 1:
			volumeLightOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Retrieve the option settings.
			//
			setOptionVars (false);

			//	Get the command.
			//
			$cmd = getCmd();
			break;
	}
	return $cmd;
}