// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  August, 2002
//
//  Description:
//		This script provides an option box dialog ghosting options.
//
//	Input Arguments:
//		boolean showOptionBox	true - show the option box dialog
//								false - just execute the command
//

//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
	// hierarchy
	//
	if ($forceFactorySettings || !`optionVar -exists unghostHier`) {
		optionVar -intValue unghostHier 0;
	}
}

//
//  Procedure Name:
//      unghostSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//		forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc unghostSetup(string $parent, int $forceFactorySettings)
{
	//	Retrieve the option settings
	//
	setOptionVars($forceFactorySettings);

	setParent $parent;

	//	Query the optionVar's and set the values into the controls.

	// hierarchy
	//
	checkBoxGrp -edit -value1 `optionVar -query unghostHier` unghostHierCheckBox;
}

//
//  Procedure Name:
//      unghostCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//		doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc unghostCallback(string $parent, int $doIt)
{
    setParent $parent;

	//	Set the optionVar's from the control values, and then
	//	perform the command.

	// hierarchy
	//
	optionVar -intValue unghostHier `checkBoxGrp -query -value1 unghostHierCheckBox`;

	if ($doIt) {
		performUnghost 0; 
		addToRecentCommandQueue "performUnghost 0" "Unghost";
	}
}

//
//  Procedure Name:
//      unghostOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc unghostOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "unghost";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	//	Get the option box.
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	Pass the command name to the option box.
	//
	setOptionBoxCommandName($commandName);
	
	//	Activate the default UI template.
	//
	setUITemplate -pushTemplate DefaultTemplate;

	//	Turn on the wait cursor.
	//
	waitCursor -state 1;

	tabLayout -scrollable true -tabsVisible false;
	string $parent = `columnLayout -adjustableColumn 1`;
	
	checkBoxGrp -label (uiRes("m_performUnghost.kHierarchy")) 
		-label1 " " unghostHierCheckBox;

	//	Turn off the wait cursor.
	//
	waitCursor -state 0;
	
	//	Deactivate the default UI template.
	//
	setUITemplate -popTemplate;

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-label (uiRes("m_performUnghost.kUnghost")) 
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	//	Set the option box title.
	//
	setOptionBoxTitle((uiRes("m_performUnghost.kUnghostOptions")));

	//	Customize the 'Help' menu item text.
	//
	setOptionBoxHelpTag( "UnghostSelected" );

	//	Set the current values of the option box.
	//
	eval (($setup + " " + $parent + " " + 0));	
	
	//	Show the option box.
	//
	showOptionBox();
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc string assembleCmd()
{
	string $setAttrCmds;

	// there should be no modification to ghost control type during unghosting
	//
	int $ghostControl = -1;
	int $pre = 0;
	int $post = 0;
	int $stepSize = 0;
	string $frameString;
	float $start = 0;
	float $end = 0;

	// hierarchy
	//
	int $hier = `optionVar -query unghostHier`;
	
	setOptionVars(false);

	string $cmd = ("doGhost \"2\" { \"0\"" +
				   ", \""+  $hier +"\"" +
				   ", \""+	$ghostControl +"\"" +
				   ", \""+	$pre +"\"" +
				   ", \""+	$post +"\"" +
				   ", \""+	$stepSize +"\"" +
				   ", \""+	$frameString +"\"" +
				   ", \""+	$start +"\"" +
				   ", \""+	$end +"\"}");

	return $cmd;
}

//
//  Procedure Name:
//      performUnghost
//
//  Description:
//		Enable ghosting using the corresponding 
//		option values.  This procedure will also show the option box
//		window if necessary as well as construct the command string
//		that will invoke ghost with the current option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
//  Return Value:
//      None.
//
global proc string performUnghost(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Retrieve the option settings
			//
			setOptionVars(false);

			//	Get the command.
			//
			$cmd = `assembleCmd`;

			//	Execute the command with the option settings.
			//
			evalEcho($cmd);

			break;

		//	Show the option box.
		//
		case 1:
			unghostOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Retrieve the option settings.
			//
			setOptionVars (false);

			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}