// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  Nov 24, 19987
//
//  Description:
//      This script is use to display and update the image range options.
//
//  Input Arguments:
//		None.
//
//  Return Value:
//      None.
//

proc string tvBakeTexturePanelName()
//
//  Procedure Name:
//      textureWindowPanelName
//
//  Description:
//		return the texture window panel name.
//
//  Input Arguments:
//		
//
//  Return Value:
//      texture window panel name
//
{
	string $texWinName[] = `getPanel -sty polyTexturePlacementPanel`;
	return $texWinName[0];
}

proc setOptionVars(int $forceFactorySettings)
//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
{
    if ($forceFactorySettings || !`optionVar -exists tvImageResolution`) {
        optionVar -iv tvImageResolution 9;
    }

}

global proc tvBakeTextureSetup(string $parent, int $forceFactorySettings)
//
//  Procedure Name:
//      tvBakeTextureSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//	forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
{
	setParent $parent;

	setOptionVars($forceFactorySettings);

	string $winName = tvBakeTexturePanelName();

	int $res = `optionVar -query tvImageResolution` - 4;
	optionMenuGrp -edit -select $res resolutionMenuPopup;
}

global proc tvBakeTextureCallback(string $parent, int $doIt)
//
//  Procedure Name:
//      tvBakeTextureCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//	doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
{
	optionVar -iv tvImageResolution
		(`optionMenuGrp -q -sl resolutionMenuPopup` + 4);


	if ($doIt) {
		performTextureViewBakeTextureOptions 0; 
		addToRecentCommandQueue "performTextureViewBakeTextureOptions 0" "TextureViewBakeTexture";
	}
}

global proc tvBakeTextureCheckResolution()
//
// Description:
//		Update UI to presets
// Arguments:
//
// Returns:
//
//
{
	int $ival = `optionMenuGrp -q -sl resolutionMenuPopup` + 4;
	int $resMax  = `optionVar -query tvImageResolution`;
}


//
//  Procedure Name:
//      tvBakeTextureOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc tvBakeTextureOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "tvBakeTexture";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

 	//	STEP 1:  Get the option box.
	//	============================
	//
	//	The value returned is the name of the layout to be used as
	//	the parent for the option box UI.
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	STEP 2:  Pass the command name to the option box.
	//	=================================================
	//
	//	Any default option box behaviour based on the command name is set 
	//	up with this call.  For example, updating the 'Help' menu item with
	//	the name of the command.
	//
	setOptionBoxCommandName($commandName);
	
	//	STEP 3:  Activate the default UI template.
	//	==========================================
	//
	//	Activate the default UI template so that the layout of this 
	//	option box is consistent with the layout of the rest of the 
	//	application.
	//
	setUITemplate -pushTemplate DefaultTemplate;

	//	STEP 4: Create option box contents.
	//	===================================
	//	
	//	This, of course, will vary from option box to option box.	
	//	Turn on the wait cursor.
	//
	waitCursor -state 1;

	tabLayout -tabsVisible 0 -scrollable 1;
	
	string $parent = `columnLayout -adjustableColumn 1`;

	optionMenuGrp -label (uiRes("m_performTextureViewBakeTextureOptions.kBakedTextureResolution"))
        -cc ("tvBakeTextureCheckResolution")
        resolutionMenuPopup;
	{
		menuItem -label "32 x 32" resolution32MenuItem;
		menuItem -label "64 x 64" resolution64MenuItem;
		menuItem -label "128 x 128" resolution128MenuItem;
		menuItem -label "256 x 256" resolution256MenuItem;
		menuItem -label "512 x 512" resolution512MenuItem;
		menuItem -label "1024 x 1024" resolution1024MenuItem;
        menuItem -label "2048 x 2048" resolution2048MenuItem;

		setParent -m ..;
	}

	//	Turn off the wait cursor.
	//
	waitCursor -state 0;
	
	//	Step 5: Deactivate the default UI template.
	//	===========================================
	//
	setUITemplate -popTemplate;

	//	Step 6: Customize the buttons.  
	//	==============================
	//
	//	Provide more descriptive labels for the buttons.  This is not 
	//	necessary, but in some cases, for example, a button labelled 
	//	'Create' may be more meaningful to the user than one labelled
	//	'Apply'.
	//
	//	Disable those buttons that are not applicable to the option box.
	//
	//	Attach actions to those buttons that are applicable to the option
	//	box.  Note that the 'Close' button has a default action attached 
	//	to it that will hide the window.  If a a custom action is
	//	attached to the 'Close' button then be sure to call the 'hide the
	//	option box' procedure within the custom action so that the option
	//	box is hidden properly.

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 1 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	//	Step 7: Set the option box title.
	//	=================================
	//
	setOptionBoxTitle (uiRes("m_performTextureViewBakeTextureOptions.kUVTextureEditorBaking"));

	//	Step 8: Customize the 'Help' menu item text.
	//	============================================
	//
	setOptionBoxHelpTag( "UVTextureEditorBakeTexture" );

	//	Step 9: Set the current values of the option box.
	//	=================================================
	//
	eval (($setup + " " + $parent + " " + 0));	
	
	//	Step 10: Show the option box.
	//	=============================
	//
	showOptionBox();
}


//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
	string $cmd;

	setOptionVars(false);

	int   $resMax    = `optionVar -query tvImageResolution`;
    int   $resolution = `pow 2 $resMax`;

	string $winName = tvBakeTexturePanelName();

	$cmd = "textureWindow -edit -maxResolution " 
		+ $resolution + " " +
		$winName;

	return $cmd;
}

//
//  Procedure Name:
//      performTextureViewBakeTextureOptions
//
//  Description:
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performTextureViewBakeTextureOptions(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Get the command.
			//
			$cmd = `assembleCmd`;

			//	Execute the command with the option settings.
			//
			eval($cmd);
			break;

		//	Show the option box.
		//
		case 1:
			tvBakeTextureOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}