// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//  Creation Date:  3 February, 1999
//
//  Procedure Name:
//      performSubdivDisplaySmoothnessMedium(string $operation, int $option)
//
//  Description:
//		
//
//  Input Arguments:
//		
//
//  Return Value:
//      None.
//

proc setOptionVars(int $forceFactorySettings)
{
	if ($forceFactorySettings || !`optionVar -exists subDivDispSmoothnessMediumObjsAffected`) {
		optionVar -intValue subDivDispSmoothnessMediumObjsAffected 1;
	}
}

//
//  Procedure Name:
//      subdivDisplaySmoothnessMediumSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//	forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc subdivDisplaySmoothnessMediumSetup(string $parent, int $forceFactorySettings)
{
	//	Retrieve the option settings
	//
	setOptionVars($forceFactorySettings);

	setParent $parent;

	//	Objects Affected Radio Button 
	//
	int $subdivObjsAffected = `optionVar -q subDivDispSmoothnessMediumObjsAffected`;
	radioButtonGrp -e -sl $subdivObjsAffected subdivObjsAffectedRadio;	
}

//
//  Procedure Name:
//      subdivDisplaySmoothnessMediumCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//	doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc subdivDisplaySmoothnessMediumCallback(string $parent, int $doIt)
{
    setParent $parent;

	//	Set the optionVar's from the control values, and then
	//	perform the command.

	int $subdivObjsAffected = `radioButtonGrp -q -sl subdivObjsAffectedRadio`;
	optionVar -intValue subDivDispSmoothnessMediumObjsAffected $subdivObjsAffected;

	if ($doIt) {
		performSubdivDisplaySmoothnessMedium 0; 
		addToRecentCommandQueue "performSubdivDisplaySmoothnessMedium 0" "SubdivDisplaySmoothnessMedium";
	}
}

//
//  Procedure Name:
//      subdivDisplaySmoothnessMediumOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc subdivDisplaySmoothnessMediumOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "subdivDisplaySmoothnessMedium";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	//	STEP 1:  Get the option box.
	//	============================
	//
	//	The value returned is the name of the layout to be used as
	//	the parent for the option box UI.
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	STEP 2:  Pass the command name to the option box.
	//	=================================================
	//
	//	Any default option box behaviour based on the command name is set 
	//	up with this call.  For example, updating the 'Help' menu item with
	//	the name of the command.
	//
	setOptionBoxCommandName($commandName);
	
	//	STEP 3:  Activate the default UI template.
	//	==========================================
	//
	//	Activate the default UI template so that the layout of this 
	//	option box is consistent with the layout of the rest of the 
	//	application.
	//
	setUITemplate -pushTemplate DefaultTemplate;

	//	STEP 4: Create option box contents.
	//	===================================
	//	
	//	This, of course, will vary from option box to option box.	
	
	//	Turn on the wait cursor.
	//
	waitCursor -state 1;

	//	RECOMMENDATION:  Place the UI in a 'scrollable' layout.  A 
	//	scrollable layout ensures that if the option box window is ever
	//	resized such that it's entire contents is not visible then the 
	//	scroll bars provided by the scrollable layout will allow the user
	//	to access the hidden UI.  Two layouts currently supporting 
	//	scrollable behaviour are the 'scrollLayout' and the 'tabLayout'.
	//
	// scrollLayout;
	//
	//	or...
	//

	tabLayout -tabsVisible 0 -scrollable 1;
	
	string $parent = `columnLayout -adjustableColumn 1`;
	
	//	RECOMMENDATION:  Use the 'Grp' commands where possible because
	//	they obey the formatting specified in the default template.
	//	This will result in a more consistent look throughout the
	//	application.
	//	
	radioButtonGrp -numberOfRadioButtons 2
		-label (uiRes("m_performSubdivDisplaySmoothnessMedium.kObjectsAffected"))
		-label1 (uiRes("m_performSubdivDisplaySmoothnessMedium.kActive"))
		-label2 (uiRes("m_performSubdivDisplaySmoothnessMedium.kAll")) subdivObjsAffectedRadio;
	  
	//	Turn off the wait cursor.
	//
	waitCursor -state 0;
	
	//	Step 5: Deactivate the default UI template.
	//	===========================================
	//
	setUITemplate -popTemplate;

	//	Step 6: Customize the buttons.  
	//	==============================
	//
	//	Provide more descriptive labels for the buttons.  This is not 
	//	necessary, but in some cases, for example, a button labelled 
	//	'Create' may be more meaningful to the user than one labelled
	//	'Apply'.
	//
	//	Disable those buttons that are not applicable to the option box.
	//
	//	Attach actions to those buttons that are applicable to the option
	//	box.  Note that the 'Close' button has a default action attached 
	//	to it that will hide the window.  If a a custom action is
	//	attached to the 'Close' button then be sure to call the 'hide the
	//	option box' procedure within the custom action so that the option
	//	box is hidden properly.

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	//	Step 7: Set the option box title.
	//	=================================
	//
	setOptionBoxTitle (uiRes("m_performSubdivDisplaySmoothnessMedium.kSubdivSmoothnessMediumOptions"));

	//	Step 8: Customize the 'Help' menu item text.
	//	============================================
	//
	setOptionBoxHelpTag( "DisplaySubdivSmoothnessMedium" );

	//	Step 9: Set the current values of the option box.
	//	=================================================
	//
	eval (($setup + " " + $parent + " " + 0));	
	
	//	Step 10: Show the option box.
	//	=============================
	//
	showOptionBox();
}

//
//  Procedure Name:
//      subdivDisplaySmoothnessMediumHelp
//
//  Description:
//		Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string subdivDisplaySmoothnessMediumHelp()
{
	return 
	"  Command: subdivDisplaySmoothness - Set display smoothness for subdivision surfaces\n" +
	"Selection: Subdivision Surfaces";
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
	string $cmd;

	setOptionVars(false);
	int $subdivObjsAffected = `optionVar -q subDivDispSmoothnessMediumObjsAffected`;

	if ($subdivObjsAffected == 1){
	  //
	  // Change the smoothness of only the active subdiv objects
	  //
	  $cmd = "subdivDisplaySmoothness -s 2;";
	}
	else {
	  //
	  // Change the smoothness of all subdiv objects
	  //
	  $cmd = "subdivDisplaySmoothness -s 2 -all;";
	}

	return $cmd;
}

//
//  Procedure Name:
//      performsubdivDisplaySmoothnessMedium
//
//  Description:
//		Perform the performsubdivDisplaySmoothnessMedium command using 
//      the corresponding 
//		option values.  This procedure will also show the option box
//		window if necessary as well as construct the command string
//		that will invoke the optionBoxExample1 command with the current
//		option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performSubdivDisplaySmoothnessMedium(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Get the command.
			//
			$cmd = `assembleCmd`;

			//	Execute the command with the option settings.
			//
			eval($cmd);

			break;

		//	Show the option box.
		//
		case 1:
			subdivDisplaySmoothnessMediumOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}