// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//  Description:
// 		An option window used for autobinding a container.
//

//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
	if ($forceFactorySettings || !`optionVar -exists autobindAll`) {
        // 0: unbound only
        // 1: all 
		optionVar -intValue autobindAll 0;
	}
	if ($forceFactorySettings || !`optionVar -exists autobindForce`) {
        // 0: skip unmatched values (leave them as-is) 
        // 1: process unmatched values (i.e. unbind them)
		optionVar -intValue autobindForce 0;
	}
}

//
//  Procedure Name:
//      autobindContainerSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//	forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc autobindContainerSetup(string $parent, int $forceFactorySettings)
{
	// Retrieve the option settings
	//
	setOptionVars( $forceFactorySettings );
	
	setParent $parent;

	int $autobindAll = `optionVar -q autobindAll`;
	checkBoxGrp -edit -value1 $autobindAll autobindAllWidget;

	int $autobindForce = `optionVar -q autobindForce`;
	checkBoxGrp -edit -value1 $autobindForce autobindForceWidget;


}

//
//  Procedure Name:
//     autobindContainerCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//	doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc autobindContainerCallback(string $parent, int $doIt)
{
    setParent $parent;

	optionVar -intValue autobindAll   `checkBoxGrp -q -value1 autobindAllWidget`;
	optionVar -intValue autobindForce `checkBoxGrp -q -value1 autobindForceWidget`;
	
	if ($doIt) {
		performAutobindContainer 0; 
		addToRecentCommandQueue "performAutobindContainer 0" "Autobind Asset";
	}
}

//
//  Procedure Name:
//      autobindContainerOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc autobindContainerOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "autobindContainer";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	//	STEP 1:  Get the option box.
	//	============================
	//
	//	The value returned is the name of the layout to be used as
	//	the parent for the option box UI.
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	STEP 2:  Pass the command name to the option box.
	//	=================================================
	//
	//	Any default option box behaviour based on the command name is set 
	//	up with this call.  For example, updating the 'Help' menu item with
	//	the name of the command.
	//
	setOptionBoxCommandName("containerBind");
	
	//	STEP 3:  Activate the default UI template.
	//	==========================================
	//
	//	Activate the default UI template so that the layout of this 
	//	option box is consistent with the layout of the rest of the 
	//	application.
	//
	setUITemplate -pushTemplate DefaultTemplate;

	//	STEP 4: Create option box contents.
	//	===================================
	//	
	//	This, of course, will vary from option box to option box.	
	
	//	Turn on the wait cursor.
	//
	waitCursor -state 1;

	tabLayout -tabsVisible 0 -scrollable 1;
	
	string $parent = `columnLayout -adjustableColumn 1`;
	
	$layout = `frameLayout -label (uiRes("m_performAutobindContainer.kSettings"))  -collapsable 0`;

	columnLayout;
		checkBoxGrp -label ""
			-label1 (uiRes("m_performAutobindContainer.kAutobindAll")) 
			-annotation (uiRes("m_performAutobindContainer.kAutobindAllAnnot")) 
			autobindAllWidget;

	columnLayout;
		checkBoxGrp -label ""
			-label1 (uiRes("m_performAutobindContainer.kAutobindForce")) 
			-annotation (uiRes("m_performAutobindContainer.kAutobindForceAnnot")) 
			autobindForceWidget;
		
	setParent ..;
	setParent ..;	

	//	Turn off the wait cursor.
	//
	waitCursor -state 0;
	
	//	Step 5: Deactivate the default UI template.
	//	===========================================
	//
	setUITemplate -popTemplate;

	//	Step 6: Customize the buttons.  
	//	==============================
	//
	//	Provide more descriptive labels for the buttons.  This is not 
	//	necessary, but in some cases, for example, a button labelled 
	//	'Create' may be more meaningful to the user than one labelled
	//	'Apply'.
	//
	//	Disable those buttons that are not applicable to the option box.
	//
	//	Attach actions to those buttons that are applicable to the option
	//	box.  Note that the 'Close' button has a default action attached 
	//	to it that will hide the window.  If a a custom action is
	//	attached to the 'Close' button then be sure to call the 'hide the
	//	option box' procedure within the custom action so that the option
	//	box is hidden properly.

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	//	Step 7: Set the option box title.
	//	=================================
	//
	setOptionBoxTitle (uiRes("m_performAutobindContainer.kAutobindAssetOptions"));

	//	Step 8: Customize the 'Help' menu item text.
	//	============================================
	//
	setOptionBoxHelpTag( "AutobindContainer" );

	//	Step 9: Set the current values of the option box.
	//	=================================================
	//
	eval (($setup + " " + $parent + " " + 0));	
	
	//	Step 10: Show the option box.
	//	=============================
	//
	showOptionBox();
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
	setOptionVars(false);

	int $autobindAll = 0;
	int $autobindForce = 0;
	if (`optionVar -exists autobindAll`) {
		$autobindAll = `optionVar -q autobindAll`;
	}
	if (`optionVar -exists autobindForce`) {
		$autobindForce = `optionVar -q autobindForce`;
	}

	$cmd = ("doAutobindContainer(1, {\""+$autobindAll+"\",\""+$autobindForce+"\"})");

	return $cmd;
}

//
//  Procedure Name:
//      performAutobindContainer
//
//  Description:
//		Perform the autobind using the option values.
//		This procedure will also show the option box
//		window if necessary as well as construct the command string
//		that will invoke the command with the current
//		option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performAutobindContainer(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Get the command.
			//
			$cmd = `assembleCmd`;

			//	Execute the command with the option settings.
			//
			evalEcho($cmd);

			break;

		//	Show the option box.
		//
		case 1:
			autobindContainerOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}