// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Description:
//		This script provides an option box dialog for the characterize command.
//
//	Input Arguments:
//		boolean showOptionBox	true - show the option box dialog
//								false - just execute the command
//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//		Initialize the option values.
//
//  Input Arguments:
//		Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
	//	Type: default is Labels
	//
	if ($forceFactorySettings || !`optionVar -exists fbikType`) {
		optionVar -intValue fbikType 1;
	}

	//	Posture: default is Biped
	//
	if ($forceFactorySettings || !`optionVar -exists fbikPosture`) {
		optionVar -intValue fbikType 1;
	}
}

//
//  Procedure Name:
//      addFullBodyIkSetup
//
//  Description:
//		Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be 
//                             successfully resolved.
//
//		forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc addFullBodyIkSetup(string $parent, int $forceFactorySettings)
{
	//	Retrieve the option settings
	//
	setOptionVars($forceFactorySettings);

	setParent $parent;

	//	Query the optionVar's and set the values into the controls.

	//	Type: Labels vs. Names
	//
	radioButtonGrp -edit 
		-select `optionVar -query fbikType`
		fbikTypeGrp;


	//	Posture: Biped vs Quadruped
	//
	radioButtonGrp -edit 
		-select `optionVar -query fbikPosture`
		fbikPostureGrp;
}

//
//  Procedure Name:
//      addFullBodyIkCallback
//
//  Description:
//		Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//		doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
// ********* Change 'addFullBodyIk' in this proc to be the name of your command
global proc addFullBodyIkCallback(string $parent, int $doIt)
{
    setParent $parent;

	//	Set the optionVar's from the control values, and then
	//	perform the command.

	//	Type: Labels or Names
	//
	optionVar -intValue fbikType
		`radioButtonGrp -query -select fbikTypeGrp`;

	//	Posture: biped or quadruped
	//
	optionVar -intValue fbikPosture
		`radioButtonGrp -query -select fbikPostureGrp`;

	if ($doIt) {
		performAddFullBodyIk 0; 
		addToRecentCommandQueue "performAddFullBodyIk 0" "CreateFBIK";
	}
}

//
//  Procedure Name:
//      addFullBodyIkOptions
//
//  Description:
//		Construct the option box UI.  Involves accessing the standard option
//		box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc addFullBodyIkOptions()
{
	//	Name of the command for this option box.
	//
	string $commandName = "addFullBodyIk";

	//	Build the option box actions.
	//
	string $callback = ($commandName + "Callback");
	string $setup = ($commandName + "Setup");

	//	Get the option box.
	//
	string $layout = getOptionBox();
	setParent $layout;
	
	//	Pass the command name to the option box.
	//
	setOptionBoxCommandName("characterize");
	
	//	Activate the default UI template.
	//
	setUITemplate -pushTemplate DefaultTemplate;

	//	Turn on the wait cursor.
	//
	waitCursor -state 1;

	tabLayout -scr true -tv false;

	string $parent = `columnLayout -adjustableColumn 1`;
	
	radioButtonGrp -label (uiRes("m_performAddFullBodyIk.kIdentifyJoints")) 
		-numberOfRadioButtons 2
		-label1 (uiRes("m_performAddFullBodyIk.kByLabel")) 
		-label2 (uiRes("m_performAddFullBodyIk.kByName")) 
		-select 1
		fbikTypeGrp;

	radioButtonGrp -label (uiRes("m_performAddFullBodyIk.kPosture")) 
		-numberOfRadioButtons 2
		-label1 (uiRes("m_performAddFullBodyIk.kBiped")) 
		-label2 (uiRes("m_performAddFullBodyIk.kQuadruped")) 
		-select 1
		fbikPostureGrp;

	//	Turn off the wait cursor.
	//
	waitCursor -state 0;
	
	//	Deactivate the default UI template.
	//
	setUITemplate -popTemplate;

	//	'Apply' button.
	//
	string $applyBtn = getOptionBoxApplyBtn();
	button -edit
		-label (uiRes("m_performAddFullBodyIk.kAdd")) 
		-command ($callback + " " + $parent + " " + 1)
		$applyBtn;

	//	'Save' button.
	//
	string $saveBtn = getOptionBoxSaveBtn();
	button -edit 
		-command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
		$saveBtn;

	//	'Reset' button.
	//
	string $resetBtn = getOptionBoxResetBtn();
	button -edit 
		-command ($setup + " " + $parent + " " + 1)
		$resetBtn;

	//	Set the option box title.
	//
	setOptionBoxTitle (uiRes("m_performAddFullBodyIk.kAddFullBodyIKOptions"));

	//	Customize the 'Help' menu item.
	//
	setOptionBoxHelpTag( "AddFullBodyIk" );

	//	Set the current values of the option box.
	//
	eval (($setup + " " + $parent + " " + 0));	
	
	//	Show the option box.
	//
	showOptionBox();
}

//
//  Procedure Name:
//      addFullBodyIkHelp
//
//  Description:
//		Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string addFullBodyIkHelp()
{
	return 
	"  Command: characterize - adds full body ik to a skeleton.\n" +
	"Selection: root joint";	
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//		Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc string assembleCmd()
{
	string $cmd = "characterize -pinHandFeet";

	setOptionVars(false);

	string $typeFlag;
	if (`optionVar -query fbikType` == 1) {
		$typeFlag = " -type label";
	} else {
		$typeFlag = " -type name";
	}

	string $postureFlag;
	if (`optionVar -query fbikPosture` == 1) {
		$postureFlag = " -posture biped";
	} else {
		$postureFlag = " -posture quadruped";
	}

	$cmd = ($cmd + $typeFlag + $postureFlag);
	$cmd += ";";	
	return $cmd;
}

//
//  Procedure Name:
//      performAddFullBodyIk
//
//  Description:
//		Perform the addFullBodyIk command using the corresponding 
//		option values.  This procedure will also show the option box
//		window if necessary as well as construct the command string
//		that will invoke the addFullBodyIk command with the current
//		option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
//  Return Value:
//      None.
//
global proc string performAddFullBodyIk(int $action)
{
	string $cmd = "";

	switch ($action) {

		//	Execute the command.
		//
		case 0:
			//	Retrieve the option settings
			//
			setOptionVars(false);

			//	Get the command.
			//
			$cmd = `assembleCmd`;

			//	Execute the command with the option settings.
			//
			evalEcho($cmd);

			break;

		//	Show the option box.
		//
		case 1:
			addFullBodyIkOptions;
			break;

		//	Return the command string.
		//
		case 2:
			//	Retrieve the option settings.
			//
			setOptionVars (false);

			//	Get the command.
			//
			$cmd = `assembleCmd`;
			break;
	}
	return $cmd;
}