// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
// Creation Date:  14 January 1999
//
//
//  Procedure Name:
//      offsetSurfaceToolScript
//
//  Description:
//	create wrapper around the offsetSurface command
//
//  Input Arguments:
//		0 ==> do the command.
//		1 ==> show the tool/action option box
//		2 ==> return the command
//		3 ==> show tool/action option box
//		4 ==> enter the tool
//
//  Return Value:
//      None.
//

global proc offsetSurfaceToolSetup(int $forceFactorySettings, string $goToTool)
{
	global int $gStartWithAutoComplete;
	if( $forceFactorySettings || !`optionVar -ex offsetSurfaceEuc` ) {
		optionVar -iv offsetSurfaceEuc 0;
	}
	if( $forceFactorySettings || !`optionVar -ex offsetSurfaceLac` ) {
		optionVar -iv offsetSurfaceLac $gStartWithAutoComplete;
	}
	if( "" != $goToTool ) {
		scriptCtx -e -euc `optionVar -q offsetSurfaceEuc` $goToTool;
		scriptCtx -e -lac `optionVar -q offsetSurfaceLac` $goToTool;
	}
}

global proc offsetSurfaceValues ( string $toolName ) 
{
	performOffsetSurface 3 $toolName;
	scriptCtxCommonValues( $toolName );
}

global proc offsetSurfaceProperties()
{
	scriptCtxCommonProperties;
}

proc createOffsetSurfaceContext( string $tool )
{
	if( ! `scriptCtx -exists $tool` ) {
		offsetSurfaceToolSetup( 0, "" );
		scriptCtx -i1 "offsetSurface.png"
		  -title (uiRes("m_offsetSurfaceToolScript.kOffsetCurve"))
		  -bcn "offsetSurface"

		  -exitUponCompletion `optionVar -q offsetSurfaceEuc`
		  -totalSelectionSets 1
		  -expandSelectionList true
		  -fcs ("offsetSurfaceToolScript 0")

		  -setNoSelectionPrompt (uiRes("m_offsetSurfaceToolScript.kSelectNURBSOffset"))
		  -setSelectionPrompt (uiRes("m_offsetSurfaceToolScript.kSelectMoreNURBSOffset"))
		  -setDoneSelectionPrompt (uiRes("m_offsetSurfaceToolScript.kDoneSelect"))

		  -setAutoToggleSelection true
		  -setAutoComplete `optionVar -q offsetSurfaceLac`
		  -setAllowExcessCount true
		  -showManipulators true

		  -setSelectionCount 0
		  -nurbsSurface true
		$tool;
	}
}

global proc string offsetSurfaceToolScript( int $setToTool )
//
//	Description :
//		0 ==> do the command.
//		1 ==> show the action option box
//		2 ==> return the command
//		3 ==> show tool/action option box
//		4 ==> enter the tool/do the command
{
	string $tool = "";
	if( $setToTool > 2 ) {
		if( !`optionVar -q modelWithToolOffsetSurface` ) {
			$setToTool = 4 - $setToTool;
		}
		else {
			$tool = "offsetSurfaceContext";
			createOffsetSurfaceContext $tool;
		}
	}
	return scriptToolScript( "performOffsetSurface", $setToTool, $tool );
}