// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//	General Interactive Batch render interface.
//

global proc mayaBatchRender()
{
	string $currRenderer = currentRenderer();
	string $cmd = "batchRender";
	if( $currRenderer == "mentalRay" ){
		// make sure mental ray is initialized
		miCreateDefaultNodes();

		if( `optionVar -exists "v_mrBatchRenderRenderMode"` ){
			if( `optionVar -query v_mrBatchRenderRenderMode` == 1 ){
				// Batch rendering with mrSA
				$cmd = $cmd + " -useStandalone";
				if( `optionVar -exists "v_mrBatchRenderPreRenderCommand"` ){
					string $preCmd = `optionVar -query v_mrBatchRenderPreRenderCommand`;
					if ($preCmd != "") {
						$cmd = $cmd + " -preRenderCommand \"" + $preCmd + "\"";
					}
				}
				if( `optionVar -exists "v_mrBatchRenderRenderCommand"` ){
					string $renderCmd = `optionVar -query v_mrBatchRenderRenderCommand`;
					$cmd = $cmd + " -melCommand \"" + $renderCmd + "\"";
				} else {
					error((uiRes("m_mayaBatchRender.kNoStandaloneCmd")));
				}

				string $extraOpts = " -renderCommandOptions \"";
				int $useExtraOpts = false;
				if( `optionVar -exists "v_mrBatchRenderRenderCommandOptions"` ){
					string $cmdOpts = `optionVar -query v_mrBatchRenderRenderCommandOptions`;
					if ($cmdOpts != "") {
						$extraOpts = $extraOpts + $cmdOpts;
						$useExtraOpts = true;
					}
				}
				// append include/lib dirs so that they are picked up last
				if( `optionVar -exists "v_mrBatchRenderRenderCommandOptionsInclude"` ){
					string $cmdOpts = `optionVar -query v_mrBatchRenderRenderCommandOptionsInclude`;
					if ($cmdOpts != "") {
						$extraOpts = $extraOpts + " -I \\\\\\\"" + $cmdOpts + "\\\\\\\"";
						$useExtraOpts = true;
					}
				}
				if( `optionVar -exists "v_mrBatchRenderRenderCommandOptionsLib"` ){
					string $cmdOpts = `optionVar -query v_mrBatchRenderRenderCommandOptionsLib`;
					if ($cmdOpts != "") {
						$extraOpts = $extraOpts + " -L \\\\\\\"" + $cmdOpts + "\\\\\\\"";
						$useExtraOpts = true;
					}
				}
				if ($useExtraOpts) {
					$extraOpts = $extraOpts + "\"";
					$cmd = $cmd + $extraOpts;
				}

				evalString $cmd;
				return;
			}
		}
	}


	// get renderer specific flags to 'Render' executable
	string $optsProc = `renderer -q -batchRenderOptionsStringProcedure $currRenderer`;
	string $cmdOpts = "";
	if ($optsProc != "") {
		$cmdOpts = `eval $optsProc`;
	}

	$cmd = $cmd + " -renderCommandOptions \"-interactive 1 " + $cmdOpts + "\" ";
	evalString $cmd;
}