// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
// Creation Date:  14 January 1999
//
//
//  Procedure Name:
//      fitBsplineToolScript
//
//  Description:
//	create wrapper around the fitBspline command
//
//  Input Arguments:
//		0 ==> do the command.
//		1 ==> show the tool/action option box
//		2 ==> return the command
//		3 ==> show tool/action option box
//		4 ==> enter the tool
//
//  Return Value:
//      None.
//

global proc fitBsplineToolSetup( int $forceFactorySettings, string $goToTool )
{
	if( $forceFactorySettings || !`optionVar -ex fitBsplineEuc` ) {
		optionVar -iv fitBsplineEuc 0;
	}
	if( $forceFactorySettings || !`optionVar -ex fitBsplineLac` ) {
		optionVar -iv fitBsplineLac 1;
	}
	if( "" != $goToTool ) {
		scriptCtx -e -euc `optionVar -q fitBsplineEuc` $goToTool;
		scriptCtx -e -lac `optionVar -q fitBsplineLac` $goToTool;
	}
}

global proc fitBsplineValues ( string $toolName ) 
{
	performFitBspline 3 $toolName;
	scriptCtxCommonValues( $toolName );
}

global proc fitBsplineProperties()
{
	scriptCtxCommonProperties;
}

proc createFitBsplineContext( string $tool )
{
	if( ! `scriptCtx -exists $tool` ) {
		fitBsplineToolSetup( 0, "" );
		scriptCtx -i1 "fitBSpline.png"
			-title (uiRes("m_fitBsplineToolScript.kFitBsplineTool"))
			-bcn "fitBspline"

			-exitUponCompletion `optionVar -q fitBsplineEuc`
			-totalSelectionSets 1
			-expandSelectionList true
			-fcs ("fitBsplineToolScript 0")

			-setNoSelectionPrompt (uiRes("m_fitBsplineToolScript.kSelectCurves"))
			-setSelectionPrompt (uiRes("m_fitBsplineToolScript.kSelectAdditionalCurves"))

			-setAutoToggleSelection true
			-setAutoComplete `optionVar -q fitBsplineLac`
			-setAllowExcessCount true
			-showManipulators true

			-setSelectionCount 0
			-nurbsCurve true
			-isoparm true
			-curveOnSurface true
			-surfaceEdge true
			-polymeshEdge true
		$tool;
	}
}

global proc string fitBsplineToolScript( int $setToTool )
//
//	Description :
//		0 ==> do the command.
//		1 ==> show the action option box
//		2 ==> return the command
//		3 ==> show tool/action option box
//		4 ==> enter the tool/do the command
{
	string $tool = "";
	if( $setToTool > 2 ) {
		if( !`optionVar -q modelWithToolFitBspline` ) {
			$setToTool = 4 - $setToTool;
		}
		else {
			$tool = "fitBsplineContext";
			createFitBsplineContext $tool;
		}
	}
	return scriptToolScript( "performFitBspline", $setToTool, $tool );
}