// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:  26 Feb 1996
//
//  Description:
//      This procedure is a callback for the drag/drop on deformers

global proc dropDeformersReorder( string $dragged, string $drop, string $msgs[],
								  int $x, int $y, int $type )
{
	if( $dragged == $drop ) return;
	if( size($msgs) < 1 ) return;
	if( "deformersReorder" != $msgs[0] ) return;

	global string $gHistoryWindowNode;

	string $nameDragged = "";
	string $nameDropped = "";
	string $annDragged = "";
	string $annDropped = "";
	string $object = "";
	string $tmpobj = "";
	int $future = false;
	string $tmp[];
	int $n;

	if( "staticText" == `objectTypeUI $dragged` ) {
		$annDragged = `text -q -ann $dragged`;
	}
	if( "staticText" == `objectTypeUI $drop` ) {
		$annDropped = `text -q -ann $drop`;
	}

	if( ("" != $annDragged) && ("" != $annDropped) ) {
		tokenize( $annDropped, "|", $tmp );
		$n = size($tmp);
		if( $n > 2 ) {
			$object = $tmp[0];
			for( $i=1; $i<($n-2); $i+=1 ) {
				$object = $object + "|" + $tmp[$i];
			}
			if( "future" == $tmp[$n-2] ) {
				$future = true;
			}
			$nameDropped = $tmp[$n-1];

			tokenize( $annDragged, "|", $tmp );
			$n = size($tmp);
			if( $n > 2 ) {
				$tmpobj = $tmp[0];
				for( $i=1; $i<($n-2); $i+=1 ) {
					$tmpobj = $tmpobj + "|" + $tmp[$i];
				}

				$nameDragged = $tmp[$n-1];

				if( $tmpobj != $object ) {
					warning( (uiRes("m_dropDeformersReorder.kWarningMismatchedTargets")) );
				}
			}
			else {
				error( (uiRes("m_dropDeformersReorder.kErrorBadDragName")) );
			}
		}
		else {
			error( (uiRes("m_dropDeformersReorder.kErrorBadDropName")) );
		}
	}

	if( ("" != $nameDragged) && ("" != $nameDropped) ) {
		// Force the window to rebuild itself even though the selection
		// has not changed
		$gHistoryWindowNode = "";
		
		evalEcho( "reorderDeformers \"" + $nameDropped +
				  "\" \"" + $nameDragged + "\" \"" + $object + "\"" );
		evalDeferred( "historyPopupFill \"" + $object + "\" " + $future + " 2");
	}
}