// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
global proc deleteEntireHairSystem()
{
	string $startSelect[] = `ls -sl`;
	convertHairSelection( "hairSystems" );
	string $hsys[] = `ls -sl`;
	if( size( $hsys ) < 1 ){
		warning( (uiRes("m_deleteEntireHairSystem.kNoHairSystemForDelete")) );
		select -r $startSelect;
		return;
	}

	convertHairSelection( "follicles" );
	string $follicles[] = `ls -sl`;
	convertHairSelection( "startCurves" );
	string $startCurves[] = `ls -sl`;
	select -r $follicles;
	convertHairSelection( "restCurves" );
	string $restCurves[] = `ls -sl`;
	select -r $follicles;
	convertHairSelection( "current" );
	string $current[] = `ls -sl`;
	select -r $follicles;
	convertHairSelection( "constraints" );
	string $constraints[] = `ls -sl`;
	string $hsysGroups[];
	int $i, $j = 0;
	for( $i = 0; $i < size( $hsys ); $i++ ){
		string $tforms[] = listTransforms( $hsys[$i] );
		if( size( $tforms ) > 0 ){
			$hsysGroups[$j] = $tforms[0];
			$j++;
		}
		string $groups[] = getHairSystemGroups( $hsys[$i], false );
		if( $groups[0] != "" ){
			$hsysGroups[$j] = $groups[0];
			$j++;
		}
		if( $groups[1] != "" ){
			$hsysGroups[$j] = $groups[1];
			$j++;
		}
	}
	
	if(`pluginInfo -q -l Fur`) {	
		for( $i = 0; $i < size( $hsys ); $i++ ){
			string $curveAttractorSet[] = `listConnections -shapes true -type "FurCurveAttractors" $hsys[$i]`;
			if(size($curveAttractorSet) == 1)
				HfDeleteCAS $curveAttractorSet[0];
		}
	}

	string $all[];
	appendStringArray( $all, $hsys, size($hsys));
	appendStringArray( $all, $follicles, size($follicles));
	appendStringArray( $all, $startCurves, size($startCurves));
	appendStringArray( $all, $restCurves, size($restCurves));
	appendStringArray( $all, $current, size($current));
	appendStringArray( $all, $constraints, size($constraints));
	appendStringArray( $all, $hsysGroups, size($hsysGroups));
	delete $all;
	select -r;
}