// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================

global proc createPolySphereProperties()
{
	// Global template variables for form spacing
	global int $gToolOptionBoxTemplateDescriptionMarginWidth;
	global int $gToolOptionBoxTemplateFrameSpacing;
	
	string $parent = `toolPropertyWindow -q -location`;
	setParent $parent;
	
	setUITemplate -pushTemplate ToolOptionBoxTemplate;

	string $type = "createPolySphere";
	string $title = (uiRes("m_createPolySphereProperties.kCreatePolySphereToolSettings"));

	string $axis = `upAxis -q -axis`;
	
	int $axisButton = 1;
	
	if ($axis == "z")
		$axisButton = 2;
	else
		$axisButton = 1;
		
	// Form layout
	$parent = `formLayout $type`;

		// Description frame
		string $descriptionFrame = 
		`frameLayout -label (uiRes("m_createPolySphereProperties.kDescriptionFrame")) -mw $gToolOptionBoxTemplateDescriptionMarginWidth`;

			text -label (uiRes("m_createPolySphereProperties.kCreatePolySphereToolDescApp")) createPolySphereToolDescLabel;			
	
		setParent $parent;


		// Single-click Settings frame
		string $singleClickSettingsFrame = 
		`frameLayout -label (uiRes("m_createPolySphereProperties.kSettingsFrame"))`;
			columnLayout;

				floatSliderGrp -field true -l (uiRes("m_createPolySphereProperties.kRadius"))
					-min 0.01 -max 10.0 -v 1.0 -fieldMaxValue 10000 createPolySphereRadiusSlider;
					
				radioButtonGrp -label (uiRes("m_createPolySphereProperties.kAxis"))
					-numberOfRadioButtons 3
					-label1 (uiRes("m_createPolySphereProperties.kXAxis"))
					-label2 (uiRes("m_createPolySphereProperties.kYAxis"))
					-label3 (uiRes("m_createPolySphereProperties.kZAxis"))
					-enable true
					-select $axisButton
					createPolySphereAxisRadioButton;
					
		setParent $parent;	
		
		string $adjustFrame = 
		`frameLayout -label (uiRes("m_createPolySphereProperties.kAdjustmentAfterCreateSettings"))`;
			columnLayout;
											
				checkBoxGrp -label1 (uiRes("m_createPolySphereProperties.kDoDragEditLine"))
					-value1 false
					-enable true
					createPolySphereDragEditCheckBox;

		setParent $parent;
		
		// Create Settings frame
		string $settingsFrame = 
		`frameLayout -label (uiRes("m_createPolySphereProperties.kCreateSettingsFrame"))`;
			columnLayout;

				intSliderGrp -field true -l (uiRes("m_createPolySphereProperties.kAxisDivisions"))
					-min 1 -max 50 -fmx 10000 -v 1 createPolySphereWidthDivisionsSlider;

				intSliderGrp -field true -l (uiRes("m_createPolySphereProperties.kHeightDivisions"))
					-min 1 -max 50 -fmx 10000 -v 1 createPolySphereHeightDivisionsSlider;
				
				checkBoxGrp -label1 (uiRes("m_createPolySphereProperties.kCreateUVs"))
					-label (uiRes("m_createPolySphereProperties.kTextureMapping"))
					-value1 true
					-enable true
					createPolySphereCreateUVCheckBox;
				
				radioButtonGrp
					-numberOfRadioButtons 2
					-label1 (uiRes("m_createPolySphereProperties.kSawtooth"))
					-label2 (uiRes("m_createPolySphereProperties.kPinched")) 				
					-select 1
					-enable true
					-vertical
					createPolySphereUVPoleTypeRadioButton;
			
		setParent ..;
		

	// Attach Description/Settings frames to form layout
	formLayout -e
		-af $descriptionFrame "top" $gToolOptionBoxTemplateFrameSpacing
		-af $descriptionFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $descriptionFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $descriptionFrame "bottom"

		-ac $singleClickSettingsFrame "top" $gToolOptionBoxTemplateFrameSpacing $descriptionFrame
		-af $singleClickSettingsFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $singleClickSettingsFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $singleClickSettingsFrame "bottom" 

		-ac $settingsFrame "top" $gToolOptionBoxTemplateFrameSpacing $singleClickSettingsFrame
		-af $settingsFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $settingsFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $settingsFrame "bottom" 

		-ac $adjustFrame "top" $gToolOptionBoxTemplateFrameSpacing $settingsFrame
		-af $adjustFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $adjustFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $adjustFrame "bottom" 
		
	$parent;

	setUITemplate -popTemplate;
}