// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================

global proc createNurbsTorusValues(string $toolName)
{
	string $name = "createNurbsTorus";
	string $parent = (`toolPropertyWindow -q -location` + "|" + $name);
	setParent $parent;

	float	$startSweep		= `createNurbsTorusCtx -q -startSweep $toolName`;
	float	$endSweep		= `createNurbsTorusCtx -q -endSweep $toolName`;
	float	$minorSweep		= `createNurbsTorusCtx -q -minorSweep $toolName`;
	float	$minorRadius	= `createNurbsTorusCtx -q -minorRadius $toolName`;
	int		$sections		= `createNurbsTorusCtx -q -sections $toolName`;
	int		$spans			= `createNurbsTorusCtx -q -spans $toolName`;
	float	$rad			= `createNurbsTorusCtx -q -radius $toolName`;
	int		$surfDeg		= `createNurbsTorusCtx -q -surfaceDegree $toolName`;
	int		$toleranceType	= (`createNurbsTorusCtx -q -toleranceType $toolName`);
	int		$tolerance		= `createNurbsTorusCtx -q -tolerance $toolName`;
	int 	$axisType		= `createNurbsTorusCtx -q -axisType $toolName`;
	float	$axis[3]		= `createNurbsTorusCtx -q -axis $toolName`;
	
	int $dragEdit = `createNurbsTorusCtx -q -doDragEdit $toolName`;		
	
	// Set control values and callbacks
	//	
	if( $axisType < 4 ) {
		radioButtonGrp -edit -select $axisType createNurbsTorusAxisType1RadioButtonGrp;
	} else {
		radioButtonGrp -edit -select ($axisType - 3) createNurbsTorusAxisType2RadioButtonGrp;
	}

	radioButtonGrp -edit 
		-onCommand1 ("floatFieldGrp -e -value 1.0 0.0 0.0 0.0 createNurbsTorusAxisFieldsFloatGrp; createNurbsTorusCtx -edit -axisType 1 -axis 1 0 0 " + $toolName )
		-onCommand2 ("floatFieldGrp -e -value 0.0 1.0 0.0 0.0 createNurbsTorusAxisFieldsFloatGrp; createNurbsTorusCtx -edit -axisType 2 -axis 0 1 0 " + $toolName )
		-onCommand3 ("floatFieldGrp -e -value 0.0 0.0 1.0 0.0 createNurbsTorusAxisFieldsFloatGrp; createNurbsTorusCtx -edit -axisType 3 -axis 0 0 1 " + $toolName )
		createNurbsTorusAxisType1RadioButtonGrp;
		
	radioButtonGrp -edit
		-onCommand1 ("createNurbsTorusCtx -edit -axisType 4 -axis " +
						"`floatFieldGrp -query -value1 createNurbsTorusAxisFieldsFloatGrp` " +
						"`floatFieldGrp -query -value2 createNurbsTorusAxisFieldsFloatGrp` " +
						"`floatFieldGrp -query -value3 createNurbsTorusAxisFieldsFloatGrp` " +
						$toolName )
		-onCommand2 ("float $axis[] = `nurbsViewDirectionVector 1`; createNurbsTorusCtx -edit -axisType 5 -axis $axis[0] $axis[1] $axis[2] " + $toolName )					
		createNurbsTorusAxisType2RadioButtonGrp;

	floatFieldGrp -edit 
		-enable ($axisType == 4)
		-value $axis[0] $axis[1] $axis[2] 0.0
		-changeCommand ("createNurbsTorusCtx -e -axis #1 #2 #3 " + $toolName)
		-value1 $axis[0] 
		-value2 $axis[1] 
		-value3 $axis[2]
		createNurbsTorusAxisFieldsFloatGrp;

	radioButtonGrp -e 
		-select ($surfDeg == 3 ? 2 : 1)
		-onCommand1 ("createNurbsTorusCtx -e -surfaceDegree 1 " + $toolName)
		-onCommand2 ("createNurbsTorusCtx -e -surfaceDegree 3 " + $toolName)
		createNurbsTorusSurfaceDegreeRadioButtonGrp;

	floatSliderGrp -e
		-v $startSweep
		-cc ("createNurbsTorusCtx -e -startSweep #1 " + $toolName)
		createNurbsTorusStartSweepSlider;

	floatSliderGrp -e
		-v $endSweep
		-cc ("createNurbsTorusCtx -e -endSweep #1 " + $toolName)
		createNurbsTorusEndSweepSlider;

	floatSliderGrp -e
		-v $minorSweep
		-cc ("createNurbsTorusCtx -e -minorSweep #1 " + $toolName)
		createNurbsTorusMinorSweepSlider;

	floatSliderGrp -e
		-v $minorRadius
		-cc ("createNurbsTorusCtx -e -minorRadius #1 " + $toolName)
		createNurbsTorusMinorRadiusSlider;

	intSliderGrp -e 
		-v $sections
		-cc ("createNurbsTorusCtx -e -sections #1 " + $toolName)
		createNurbsTorusSectionsSlider;

	intSliderGrp -e 
		-v $spans
		-cc ("createNurbsTorusCtx -e -spans #1 " + $toolName)
		createNurbsTorusSpansSlider;

	radioButtonGrp -edit
		-select $toleranceType
		-onCommand1 ("createNurbsTorusCtx -edit -toleranceType 1 -useTolerance 0 " + $toolName)
		-onCommand2 ("createNurbsTorusCtx -edit -toleranceType 2 -useTolerance 1 -tolerance `floatSliderGrp -query -value createNurbsTorusToleranceSlider` " + $toolName)
		-onCommand3 ("createNurbsTorusCtx -edit -toleranceType 3 -useTolerance 1 " + $toolName)
		createNurbsTorusToleranceRadioButtonGrp;
		
	if( $toleranceType == 1 ){
		
		tabLayout -edit
			-visible true -selectTab createNurbsTorusTabWithoutTolerance
			createNurbsTorusTabLayoutForTolerance;
			
	} else {
		
		if( $toleranceType == 2 ){
			
			tabLayout -edit
				-visible true -selectTab createNurbsTorusTabWithTolerance
				createNurbsTorusTabLayoutForTolerance;
				
		} else {
			
			tabLayout -edit
				-visible false
				createNurbsTorusTabLayoutForTolerance;
		}
	}
	
	floatSliderGrp -edit
		-value $tolerance
		-changeCommand ("createNurbsTorusCtx -edit -tolerance #1 " + $toolName)
		createNurbsTorusToleranceSlider;
	
	floatSliderGrp -e
		-v $rad
		-cc ("createNurbsTorusCtx -e -radius #1 " + $toolName)
		createNurbsTorusRadiusSlider;
	
	checkBoxGrp -e
		-v1 $dragEdit
		-cc1 ("createNurbsTorusCtx -e -doDragEdit " + !$dragEdit + " " + $toolName)
		createNurbsTorusDragEditCheckBox;

	string $icon = "torus.png";
	string $helpTag= "CreateNurbsTorusTool";
	toolPropertySetCommon $toolName $icon $helpTag;
	toolPropertySelect $name;
}