// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================

global proc createNurbsCircleProperties()
{
	// Global template variables for form spacing
	global int $gToolOptionBoxTemplateDescriptionMarginWidth;
	global int $gToolOptionBoxTemplateFrameSpacing;
	
	string $parent = `toolPropertyWindow -q -location`;
	setParent $parent;
	
	setUITemplate -pushTemplate ToolOptionBoxTemplate;

	string $type = "createNurbsCircle";

	// Form layout
	$parent = `formLayout $type`;

		// Description frame
		string $descriptionFrame = 
		`frameLayout -label (uiRes("m_createNurbsCircleProperties.kDescriptionFrame")) -mw $gToolOptionBoxTemplateDescriptionMarginWidth`;

			text -label (uiRes("m_createNurbsCircleProperties.kDescription"));			
	
		setParent $parent;

		// Create settings frame
		string $createSettingsFrame = 
		`frameLayout -label (uiRes("m_createNurbsCircleProperties.kCreateSettingsFrame"))`;
			columnLayout;
			
				floatSliderGrp 
					-field true 
					-label (uiRes("m_createNurbsCircleProperties.kSweepAngle"))
					-minValue 0.0 
					-maxValue 360.0 
					createNurbsCircleSweepSlider;
					
				radioButtonGrp 
					-label (uiRes("m_createNurbsCircleProperties.kDegree"))
					-numberOfRadioButtons 2
					-label1 (uiRes("m_createNurbsCircleProperties.kLinear"))
					-label2 (uiRes("m_createNurbsCircleProperties.kCubic"))
					createNurbsCircleDegree;
					
				// "Tolerance" disappears when "Use Tolerance" is false.
				// "Sections" disappears when "Use Tolerance" is true.
				// Note that the "-rational" flag no longer exists for
				// the circle command.  We do things as if the "-rational"
				// flag were always false.

				radioButtonGrp 
					-numberOfRadioButtons 3
					-label (uiRes("m_createNurbsCircleProperties.kUseTolerance"))
					-label1 (uiRes("m_createNurbsCircleProperties.kNone"))
					-label2 (uiRes("m_createNurbsCircleProperties.kLocal"))
					-label3 (uiRes("m_createNurbsCircleProperties.kGlobal"))
					createNurbsCircleUseTolerance;
					
				tabLayout -tabsVisible false createNurbsCircleTabLayoutForTolerance;
					
					columnLayout createNurbsCircleTabWithoutTolerance;
						
						intSliderGrp 	
							-label (uiRes("m_createNurbsCircleProperties.kNumberOfSections"))
							-field true
							-minValue 4 
							-maxValue 50 
							-fieldMaxValue 200
							createNurbsCircleSectionsSlider;
				
				setParent ..;
											
					columnLayout createNurbsCircleTabWithTolerance;
						
						floatSliderGrp 
							-label  (uiRes("m_createNurbsCircleProperties.kPositionalTolerance"))
							-minValue 0.001 
							-maxValue 1 
							-fieldMaxValue 100.0
							createNurbsCircleToleranceSlider;
								
					
					setParent ..;
					
				setParent ..;
				

		setParent $parent;	
		
		string $adjustFrame = 	
		`frameLayout -label (uiRes("m_createNurbsCircleProperties.kAdjustmentAfterCreateSettings"))`;
			columnLayout;
			
				checkBoxGrp -label1 (uiRes("m_createNurbsCircleProperties.kDoDragEditLine"))
					-value1 false
					-enable true
					createNurbsCircleDragEditCheckBox;			
						
		setParent $parent;	
		
		// Single-click settings frame
		string $singleClickSettingsFrame = 
		`frameLayout -label (uiRes("m_createNurbsCircleProperties.kSingleClickSettingsFrame"))`;
			columnLayout;

				floatSliderGrp 
					-label (uiRes("m_createNurbsCircleProperties.kRadius"))
					-fieldMinValue -1000.0 
					-fieldMaxValue 1000.0
					createNurbsCircleRadiusSlider;
					
				radioButtonGrp 
					-label (uiRes("m_createNurbsCircleProperties.kAxis"))
					-numberOfRadioButtons 3
					-label1 (uiRes("m_createNurbsCircleProperties.kAxisX"))
					-label2 (uiRes("m_createNurbsCircleProperties.kAxisY"))
					-label3 (uiRes("m_createNurbsCircleProperties.kAxisZ"))
					createNurbsCircleAxisType1;

				radioButtonGrp
					-numberOfRadioButtons 2
					-label1 (uiRes("m_createNurbsCircleProperties.kFree"))
					-label2 (uiRes("m_createNurbsCircleProperties.kActiveView"))
					-shareCollection "createNurbsCircleAxisType1"
					createNurbsCircleAxisType2;
					
				floatFieldGrp 
					-label (uiRes("m_createNurbsCircleProperties.kAxisDefinition"))
					-numberOfFields 3
					createNurbsCircleAxis;


		setParent $parent;	

	setParent ..;

	// Attach Description/Settings frames to form layout
	formLayout -edit
		-attachForm $descriptionFrame "top" $gToolOptionBoxTemplateFrameSpacing
		-attachForm $descriptionFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-attachForm $descriptionFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-attachNone $descriptionFrame "bottom"

		-attachControl $createSettingsFrame "top" $gToolOptionBoxTemplateFrameSpacing $descriptionFrame
		-attachForm $createSettingsFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-attachForm $createSettingsFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-attachNone $createSettingsFrame "bottom" 
		
		-ac $adjustFrame "top" $gToolOptionBoxTemplateFrameSpacing $createSettingsFrame
		-af $adjustFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-af $adjustFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-an $adjustFrame "bottom" 
		
		-ac $singleClickSettingsFrame "top" $gToolOptionBoxTemplateFrameSpacing $adjustFrame
		-attachForm $singleClickSettingsFrame "left" $gToolOptionBoxTemplateFrameSpacing
		-attachForm $singleClickSettingsFrame "right" $gToolOptionBoxTemplateFrameSpacing
		-attachNone $singleClickSettingsFrame "bottom" 

	$parent;

	setUITemplate -popTemplate;
}