// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//	Description:
//		Creates only the main layout without filling in the controls
//
global proc createBatchRenderOptionsLayout()
{
	global string $gBatchRenderWindow = "batchRenderWnd";

    string $iconName = (uiRes("m_createBatchRenderOptionsLayout.kBatchRender"));
    window -iconName $iconName
    	-rtf true
    	$gBatchRenderWindow
    	;

	// Create the appropriate layouts to house the separate software
	// and mental ray layouts.  Create an empty tab for renderers with
	// no batch options.
	formLayout batchRenderOptionsForm;
	tabLayout batchRenderOptionsTabs;

  	columnLayout mayaSoftwareBatchOptionsTab;
	setParent ..;

	columnLayout mentalRayBatchOptionsTab;
  	setParent ..;

	columnLayout nullBatchOptionsTab;
  	setParent ..;

	tabLayout -edit
		-tabsVisible false
  		-tabLabel mayaSoftwareBatchOptionsTab "mayaSoftwareBatchOptions"
		-tabLabel mentalRayBatchOptionsTab "mentalRayBatchOptions"
  		batchRenderOptionsTabs;

	setParent ..;

	button -label (uiRes("m_createBatchRenderOptionsLayout.kBatchRenderAndClose"))
		-command ("BatchRender; evalDeferred \"deleteUI -window " + $gBatchRenderWindow + "\"")
    	batchRenderAndCloseButton;
	button -label (uiRes("m_createBatchRenderOptionsLayout.kBatchRender2"))
    	batchRenderButton;
	button -label (uiRes("m_createBatchRenderOptionsLayout.kClose"))
		-c ("evalDeferred \"deleteUI -window " + $gBatchRenderWindow + "\"")
    	batchRenderCloseButton;

	formLayout -edit
    	-af batchRenderOptionsTabs "top" 5
    	-af batchRenderOptionsTabs "left" 5
    	-af batchRenderOptionsTabs "right" 5
    	-ac batchRenderOptionsTabs "bottom" 5 batchRenderAndCloseButton

    	-af batchRenderAndCloseButton "left" 5
    	-af batchRenderAndCloseButton "bottom" 5
    	-ap batchRenderAndCloseButton "right" 5 33

    	-ac batchRenderButton "left" 5 batchRenderAndCloseButton
    	-af batchRenderButton "bottom" 5
    	-ap batchRenderButton "right" 5 66

    	-ac batchRenderCloseButton "left" 5 batchRenderButton
    	-af batchRenderCloseButton "right" 5
    	-af batchRenderCloseButton "bottom" 5

    	batchRenderOptionsForm;

	scriptJob -attributeChange "defaultRenderGlobals.currentRenderer"
		"updateBatchRenderOptionsWindow"
		-parent $gBatchRenderWindow;
}