// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
// Creation Date:  14 January 1999
//
//
//  Procedure Name:
//      circFilletToolScript
//
//  Description:
//	create wrapper around the circFillet command
//
//  Input Arguments:
//		0 ==> do the command.
//		1 ==> show the action option box
//		2 ==> return the command
//		3 ==> show tool option box
//		4 ==> enter the tool
//
//  Return Value:
//      None.
//

global proc circFilletToolSetup( int $forceFactorySettings, string $goToTool )
{
	global int $gStartWithAutoComplete;
	if( $forceFactorySettings || !`optionVar -ex circFilletEuc` ) {
		optionVar -iv circFilletEuc 0;
	}
	if( $forceFactorySettings || !`optionVar -ex circFilletLac` ) {
		optionVar -iv circFilletLac $gStartWithAutoComplete;
	}
	if( "" != $goToTool ) {
		scriptCtx -e -euc `optionVar -q circFilletEuc` $goToTool;
		scriptCtx -e -lac `optionVar -q circFilletLac` $goToTool;
	}
}

global proc circFilletValues ( string $toolName ) 
{
	performCircularFillet 3 $toolName;
	scriptCtxCommonValues( $toolName );
}

global proc circFilletProperties()
{
	scriptCtxCommonProperties;
}

proc createCircFilletContext( string $tool )
{
	if( ! `scriptCtx -exists $tool` ) {
		circFilletToolSetup( 0, "" );
		scriptCtx -i1 "surfaceFillet.png"
		  -title (uiRes("m_circFilletToolScript.kCircularFilletTool"))
		  -bcn "circFillet"

		  -exitUponCompletion `optionVar -q circFilletEuc`
		  -totalSelectionSets 1
		  -expandSelectionList true
		  -fcs ("circFilletToolScript 0")

		  -setNoSelectionPrompt ((uiRes("m_circFilletToolScript.kSelectTwoSurfaces")) )
		  -setSelectionPrompt ((uiRes("m_circFilletToolScript.kSelectSecondSurface")) )
		  -setDoneSelectionPrompt ((uiRes("m_circFilletToolScript.kPressEnterToComplete")) )

		  -setAutoToggleSelection true
		  -setAutoComplete `optionVar -q circFilletLac`
		  -showManipulators true

		  -setSelectionCount 2
		  -isoparm true
		  -surfaceParameterPoint true
		$tool;
	}
}

global proc string circFilletToolScript( int $setToTool )
//
//	Description :
//		0 ==> do the command.
//		1 ==> show the action option box
//		2 ==> return the command
//		3 ==> show tool/action option box
//		4 ==> enter the tool/do the command
{
	string $tool = "";
	if( $setToTool > 2 ) {
		if( !`optionVar -q modelWithToolCircFillet` ) {
			$setToTool = 4 - $setToTool;
		}
		else {
			$tool = "circFilletContext";
			createCircFilletContext $tool;
		}
	}
	return scriptToolScript( "performCircularFillet", $setToTool, $tool );
}