// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//	Procedure Name:
//	AEhyperViewTemplate
//
//	Description Name;
//	Creates the attribute editor controls for the hyperView node
//
//	Input Value:
//	nodeName
//
//	Output Value:
//	None
//


global proc AEhyperViewDescriptionReplace ( string $description )
{

	string $conDescription = `getAttr $description`;
	textField -e  -text $conDescription 
		-cc ("setAttr " + $description + 
			" -type \"string\" " +
			" `textField -q -tx descriptionConnected`;" )
		descriptionConnected;
}


global proc AEhyperViewDescriptionNew ( string $description )
{
	setUITemplate -pst attributeEditorTemplate;

	string $conDescription = `getAttr $description`;
	rowLayout -nc 3;
		text -label (uiRes("m_AEhyperViewTemplate.kDescription"))  descriptionName;
		textField  -text $conDescription 
			-cc ("setAttr " + $description + 
				" -type \"string\" " +
				" `textField -q -tx descriptionConnected`;" )
			descriptionConnected;
		text " ";
		setParent ..;

	setUITemplate -ppt;
}


global proc AEhyperViewTemplate ( string $nodeName )
{
	editorTemplate -beginScrollLayout;
	
		editorTemplate -beginLayout (uiRes("m_AEhyperViewTemplate.kHyperViewAttributes"))  -collapse 0;
			editorTemplate -callCustom "AEhyperViewDescriptionNew"
					"AEhyperViewDescriptionReplace"
					"description";
			editorTemplate -addControl "position";
			editorTemplate -addControl "dagView";
			editorTemplate -addControl "focusNode";
			editorTemplate -addControl "buildDirection";
			editorTemplate -addControl "rootNode";
		editorTemplate -endLayout;		

		// suppressed attributes

		editorTemplate -suppress "fullName";
		editorTemplate -suppress "shortName";
		editorTemplate -suppress "viewRectLow";
		editorTemplate -suppress "viewRectHigh";

		// include/call base class/node attributes
		AEdependNodeTemplate $nodeName;

	editorTemplate -addExtraControls;
	editorTemplate -endScrollLayout;
}