// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//	Procedure Name:
//	AEextendCurveTemplate
//
//	Description Name;
//	Creates the attribute editor controls for the extendCurve node
//
//	Input Value:
//	nodeName
//
//	Output Value:
//	None
//

global proc extendCurveMethodControls( string $nodeName )
{
	string $attr = $nodeName + ".extendMethod";
	int $value = `getAttr $attr`;

	if ($value == 0) {
		editorTemplate -dimControl $nodeName "extensionType" false;
		editorTemplate -dimControl $nodeName "distance" false;
		editorTemplate -dimControl $nodeName "inputPoint" true;
	} else if ($value == 1) {
		editorTemplate -dimControl $nodeName "extensionType" false;
		editorTemplate -dimControl $nodeName "distance" true;
		editorTemplate -dimControl $nodeName "inputPoint" true;
	} else {
		editorTemplate -dimControl $nodeName "extensionType" true;
		editorTemplate -dimControl $nodeName "distance" true;
		editorTemplate -dimControl $nodeName "inputPoint" false;
	}
}

global proc extendCurveJoinControls( string $nodeName )
{
	string $attr = $nodeName + ".join";
	int $value = `getAttr $attr`;

	if ($value == 0) {
		editorTemplate -dimControl $nodeName "removeMultipleKnots" true;
	} else {
		editorTemplate -dimControl $nodeName "removeMultipleKnots" false;
	}
}

global proc AEextendCurveTemplate( string $nodeName )
{
	string $inputCurve = (uiRes("m_AEextendCurveTemplate.kInputCurve"));	
	editorTemplate -beginScrollLayout;
	
	editorTemplate -beginLayout (uiRes("m_AEextendCurveTemplate.kExtendCurveHistory")) -collapse false;
		editorTemplate -callCustom ("AEinputNew \""+$inputCurve+"\"")
					("AEinputReplace \""+$inputCurve+"\"")
					"inputCurve1";
		editorTemplate -addControl "extendMethod" "extendCurveMethodControls";
		editorTemplate -addControl "extensionType";
		editorTemplate -addControl "distance";
		editorTemplate -addControl "inputPoint";
		editorTemplate -addControl "start";
		editorTemplate -addControl "removeMultipleKnots";

	editorTemplate -endLayout;

	// include/call base class/node attributes
	AEabstractBaseCreateTemplate $nodeName;

	editorTemplate -addExtraControls;

	editorTemplate -endScrollLayout;
	
	editorTemplate -suppress "join" "extendCurveJoinControls";
	editorTemplate -suppress "inputCurve2";
	editorTemplate -suppress "inputSurface";
}