// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================
//
//
//  Creation Date:	May 14, 1997
//
//  Procedure Name:
//	AEcameraShowImagePlane
//
//  Description Name;
//	Creates the attribute editor controls to show diaply an image plane 
//	correctly in the camera editor for the camera Node
//
//  Input Value:
//	nodeName 
//
//  Output Value:
//	None
// 


global proc AEcameraShowImagePlane(string $list)
{
    string $connect[] = `listConnections $list`;
    int $i;
   
	setUITemplate -pst attributeEditorTemplate;
    	rowLayout -nc 3 AEshowLayout;
    		text -label (uiRes("m_AEcameraShowImagePlane.kCurrentImagePlanes")) ;
    		if (size($connect) == 0) {
			optionMenu -l "" AEshowMenu;
				menuItem -label (uiRes("m_AEcameraShowImagePlane.kNoImagePlanes")) ;
   			symbolButton -i "inArrow.png" -en false AEshowButtonAE;
			setParent ..;
		} else {
    			optionMenu -l "" AEshowMenu;
    			for ($i = 0; $i < size($connect); $i++)
        			menuItem -l $connect[$i] ("AEshowAE" + $i);
   			symbolButton -i "inArrow.png" 
				-c "AEcameraDisplayImagePlane" AEshowButtonAE;
			setParent ..;
		}
	setUITemplate -ppt;
}

//
//  Procedure Name:
//	AEcameraReshowImagePlane
//

global proc AEcameraReshowImagePlane(string $list)
{
    int $i;
    string $curr;

    if (`rowLayout -exists AEshowLayout`)
        deleteUI AEshowLayout;
    if (`optionMenu -exists AEshowMenu`)
        deleteUI AEshowMenu;
    if (`button -exists AEshowButtonAE`)
        deleteUI AEshowButtonAE;

    for ($i = 0; $i < 100; $i++)
    {
        $curr = ("AEshowAE" + $i);
        if (`menuItem -exists $curr`)
            deleteUI $curr;
        else
            break;
    }

    AEcameraShowImagePlane($list);
}

//
//  Procedure Name:
//	AEcameraDisplayImagePlane
//

global proc AEcameraDisplayImagePlane()
{
    string $curr = `optionMenu -q -v AEshowMenu`;
    showEditor $curr;
}