// ===========================================================================
// Copyright 2018 Autodesk, Inc. All rights reserved.
//
// Use of this software is subject to the terms of the Autodesk license
// agreement provided at the time of installation or download, or which
// otherwise accompanies this software in either electronic or hard copy form.
// ===========================================================================

global proc AEblendShapeAttrNew ( string $blendShapeMulti )
{
	string $buffer[];
	tokenize($blendShapeMulti, ".", $buffer);
	string $nodeName = $buffer[0];
	string $att	 = $buffer[1];
	

	setUITemplate -pst attributeEditorTemplate;
  
	columnLayout ($att+"Column");

	string $wts[]=`listAttr -m ($nodeName+".w")`;

	for ($i=0; $i < size($wts); $i++)
	{
		setUITemplate -pst attributeEditorTemplate;
		$sliderLabel = $wts[$i];
		$sliderName = $att+$i;
		attrFieldSliderGrp -min 0.0 -max 1.0 -fmn -10 -fmx 10.0 
			-s 0.1 -label $sliderLabel $sliderName;
		setUITemplate -ppt;
	}
	setParent ..;
	setUITemplate -ppt;
	AEblendShapeAttrReplace $blendShapeMulti;
}


global proc AEblendShapeAttrReplace ( string $blendShapeMulti )
{
	string $buffer[];
	tokenize($blendShapeMulti, ".", $buffer);
	string $nodeName = $buffer[0];
	string $att	 = $buffer[1];

	setUITemplate -pst attributeEditorTemplate;

  
	setParent ($att+"Column");
	$layoutName=`setParent -q`;
	int $oldCount=`columnLayout -q -nch $layoutName`;
	int $i;
	string $wts[]=`listAttr -m ($nodeName+".w")`;
	for ($i=0; $i < size($wts); $i++)
	{

		$attr=$nodeName+"."+$wts[$i];
		$sliderName=$att+$i;
		$sliderLabel = $wts[$i];
		if ( `attrFieldSliderGrp -ex $sliderName` )
		{
			attrFieldSliderGrp -e -label $sliderLabel -at $attr $sliderName;
		} else {
			setUITemplate -pst attributeEditorTemplate;
			attrFieldSliderGrp -min 0.0 -max 5.0 -fmn 0.0 -fmx 20.0 -s 0.1
				-label $sliderLabel -at $attr $sliderName;
			setUITemplate -ppt;
		}
	}
	for ($i=size($wts); $i < $oldCount; $i++)
	{
		$sliderName=$att+$i;
		if ( `attrFieldSliderGrp -ex $sliderName` )
			deleteUI $sliderName;
	}
	setParent ..;
	setUITemplate -ppt;
}