FunctionSpace { 
  { Name Hgrad_T; Type Form0; 
    BasisFunction { 
      { Name sn; NameOfCoef Tn; Function BF_Node; Support Tot_The; 
        Entity NodesOf[Tot_The]; } 
		
	  For i In {0:#Sur_RESISTANCE_T_List()-1}
		ThermRes_OneSideVol_i = ThermRes_OneSideVol_List(i);
		Sur_RESISTANCE_T_i = Sur_RESISTANCE_T_List(i);
				{ Name sdn ; NameOfCoef Tdn~{i} ; Function BF_Node ;
					Support ElementsOf[{ThermRes_OneSideVol_i, Sur_RESISTANCE_T_i}, 
					OnOneSideOf {Sur_RESISTANCE_T_i}] ; 
					Entity NodesOf[ {Sur_RESISTANCE_T_i}] ; }	
	  EndFor

    } 
	If (#Sur_RESISTANCE_T_List())
		SubSpace {
		{ Name Tresistance ; NameOfBasisFunction { sdn } ; }
    }
	EndIf
    Constraint { 
      { NameOfCoef Tn; EntityType NodesOf ; NameOfConstraint temperature; } 
    } 
  }

  { Name Hrgrad_flux; Type Form0; 
    BasisFunction { 
      { Name sn; NameOfCoef Tn; Function BF_Region; Support Region [{Sur_RADIATION_T, Sur_COMBINED_T}] ; 
        Entity Region [{Sur_RADIATION_T, Sur_COMBINED_T}]; } 
    } 
  	 GlobalQuantity {
    { Name U_hrflux; Type AliasOf; NameOfCoef Tn; }
	}	
  }

  { Name Hgrad_flux; Type Form0; 
    BasisFunction { 
      { Name sn; NameOfCoef Tn; Function BF_Region; Support Region [{Sur_CONVECTIVE_T, Sur_COMBINED_T}] ; 
        Entity Region [{Sur_CONVECTIVE_T, Sur_COMBINED_T}]; } 
    }
    	 GlobalQuantity {
    { Name U_hflux; Type AliasOf; NameOfCoef Tn; }
	}	
  }
}
FunctionSpace {

  // Magnetic vector potential a (b = curl a)
  { Name Hcurl_a_3D ; Type Form1 ;
    BasisFunction {// a = a_e * s_e
      { Name se ; NameOfCoef ae ; Function BF_Edge ;
        Support Region[{conducting_domain, source_domain, non_conducting_domain, stranded_source_domain, Sur_SIBC_B, Sur_INTERFACE_B}] ; Entity EdgesOf[ All, Not Sur_INFINITY_B] ; }
    }
    Constraint {
      { NameOfCoef ae  ; EntityType EdgesOf ; NameOfConstraint MVP_3D ; }
	  { NameOfCoef ae  ; EntityType EdgesOfTreeIn ; EntitySubType StartingOn ;
	NameOfConstraint Gauge ; }
    }
  }

  // Electric scalar potential (3D)
  { Name Hregion_u_3D ; Type Form1 ;
    BasisFunction {
      { Name sr ; NameOfCoef e ; Function BF_GradNode ;
        Support Region[{conducting_domain, source_domain, Sur_SIBC_B}] ; Entity NodesOf[ All , Not terms ] ; }
      { Name sr2 ; NameOfCoef estr ; Function BF_GradNode ;
        Support Region[{stranded_source_domain}] ; Entity NodesOf[ All, Not terms_str] ; }
	  { Name sc1; NameOfCoef V1; Function BF_GroupOfEdges;
	    Support Region[{conducting_domain, source_domain, Sur_SIBC_B}]; Entity GroupsOfEdgesOf[{Sur_CURRENT_B_CH, Sur_VOLTAGE_B_CH}]; }
	  { Name sc2; NameOfCoef V2; Function BF_GroupOfEdges;
	    Support Region[{stranded_source_domain}]; Entity GroupsOfEdgesOf[{SurStr_CURRENT_B_CH}]; }

	  For i In {0:#Sur_RESISTANCE_B_List()-1}
		ElecRes_OneSideVol_i = ElecRes_OneSideVol_List(i);
		Sur_RESISTANCE_B_i = Sur_RESISTANCE_B_List(i);
		{ Name sdn ; NameOfCoef edn~{i} ; Function BF_GradNode ;
			Support ElementsOf[{ElecRes_OneSideVol_i, Sur_RESISTANCE_B_i}, 
			OnOneSideOf {Sur_RESISTANCE_B_i}] ; 
			Entity NodesOf[ {Sur_RESISTANCE_B_i}] ; }	
	  EndFor
    }
	If (#Sur_RESISTANCE_B_List())
		SubSpace {
		{ Name eResistance ; NameOfBasisFunction { sdn } ; }
    }
	EndIf
	
    GlobalQuantity {
      { Name U ; Type AliasOf        ; NameOfCoef V1 ; }
      { Name I ; Type AssociatedWith ; NameOfCoef V1 ; }
      { Name Ustr ; Type AliasOf        ; NameOfCoef V2 ; }
      { Name Istr ; Type AssociatedWith ; NameOfCoef V2 ; }
    }
    Constraint {
	  { NameOfCoef e  ; EntityType NodesOf ; NameOfConstraint ElPot ; }
      { NameOfCoef U ; EntityType GroupsOfEdgesOf ; NameOfConstraint V_3D ; }
      { NameOfCoef I ; EntityType GroupsOfEdgesOf ; NameOfConstraint I_3D ; }
    }
  }
  
  // Electric scalar potential for induced voltage in stranded coil (3D)
  { Name Hregion_uStrInd_3D ; Type Form1 ;
    BasisFunction {
      { Name sr ; NameOfCoef e0 ; Function BF_GradNode ;
        Support Region[{stranded_source_domain}] ; Entity NodesOf[ All , Not terms_str ] ; }
	  { Name sc1; NameOfCoef V1; Function BF_GroupOfEdges;
	Support Region[{stranded_source_domain}]; Entity GroupsOfEdgesOf[{SurStr_CURRENT_B_CH}]; }
    }
	
    GlobalQuantity {
      { Name Ustr_ind ; Type AliasOf        ; NameOfCoef V1 ; }
      { Name Istr_ind ; Type AssociatedWith ; NameOfCoef V1 ; }
    }
  }
  
  
  // Electric scalar potential for stranded coil (3D)
  { Name Hregion_u0_3D ; Type Form1 ;
    BasisFunction {
      { Name sr ; NameOfCoef e0 ; Function BF_GradNode ;
        Support Region[{stranded_source_domain}] ; Entity NodesOf[ All , Not terms_str ] ; }
	  { Name sc1; NameOfCoef V1; Function BF_GroupOfEdges;
	Support Region[{stranded_source_domain}]; Entity GroupsOfEdgesOf[{SurStr_CURRENT_B_CH}]; }
    }
	
    GlobalQuantity {
      { Name U0 ; Type AliasOf        ; NameOfCoef V1 ; }
      { Name I0 ; Type AssociatedWith ; NameOfCoef V1 ; }
    }
    Constraint {
	  { NameOfCoef e0  ; EntityType NodesOf ; NameOfConstraint ElPot ; }
      { NameOfCoef U0 ; EntityType GroupsOfEdgesOf ; NameOfConstraint V_3D ; }
      { NameOfCoef I0 ; EntityType GroupsOfEdgesOf ; NameOfConstraint I_3D ; }
    }
  }

  /* Dummy fspace for air */
    { Name airLinSpace ; Type Form0 ;
      BasisFunction {
        { Name sn ; NameOfCoef ln ; Function BF_GroupOfNodes ;
          Support Region[{non_conducting_domain}] ; Entity GroupsOfNodesOf[ Sur_INTERFACE_B ] ; }
      }
      Constraint {
        { NameOfCoef ln ; EntityType GroupsOfNodesOf ; NameOfConstraint Lin3D ; }
      }
    }

}