Formulation { 


  { Name aFormulation ; Type FemEquation ;
    Quantity {
      { Name a  ; Type Local ; NameOfSpace Hcurl_a_3D ; }

      { Name e  ; Type Local ; NameOfSpace Hregion_u_3D ; } //Massive conductor
	  { Name I  ; Type Global ; NameOfSpace Hregion_u_3D [I] ; }
      { Name U  ; Type Global ; NameOfSpace Hregion_u_3D [U] ; }
	  { Name T;  Type Local; NameOfSpace Hgrad_T; }

    }

    Equation {
      Galerkin { [ 1/(mu[]*mu0) * Dof{d a} , {d a} ] ;
        In Region[{non_conducting, conducting, source}] ; Jacobian JVol ; Integration I1 ; }
      Galerkin { DtDof[ sigma[<T>[{T}]] * Dof{a} , {a} ] ;
        In Region[{conducting, source}] ; Jacobian JVol ; Integration I1 ; }
      Galerkin { [ sigma[<T>[{T}]] * Dof{e} , {a} ] ;
        In Region[{conducting, source}] ; Jacobian JVol ; Integration I1 ; }

      Galerkin { DtDof[ sigma[<T>[{T}]] * Dof{a} , {e} ] ;
        In Region[{conducting, source}] ; Jacobian JVol ; Integration I1 ; }
      Galerkin { [ sigma[<T>[{T}]] * Dof{e} , {e} ] ;
        In Region[{conducting, source}] ; Jacobian JVol ; Integration I1 ; }
      GlobalTerm {  [ - Dof{I}, {U} ] ; In Region[{Sur_CURRENT_CH, Sur_VOLTAGE_CH}]; }

    }
  }
   
  { Name bFormulation ; Type FemEquation; 
    Quantity { 
	  { Name a ; Type Local ; NameOfSpace Hcurl_a_3D; }
      { Name e; Type Local ; NameOfSpace Hregion_u_3D; }
      { Name T;  Type Local; NameOfSpace Hgrad_T; }
    } 
    Equation {
      Galerkin { [ lambda[{T}] * Dof{d T} , {d T} ]; 
                 In Vol_The; Integration I1; Jacobian JVol;  } 
      Galerkin { DtDof [ rho[{T}] * cp[{T}] * Dof{T} , {T} ]; 
                 In Vol_The; Integration I1; Jacobian JVol;  } 				 
      Galerkin { [ -0.5 * sigma[] * <a>[SquNorm[Dt[{a}]+{e}]], {T} ]; 
                 In Vol_The; Integration I1; Jacobian JVol;  } 
	  Galerkin { [ rho[{T}] * cp[{T}] * Vector[Velocity_x[], Velocity_y[], Velocity_z[]] * Dof{Grad T},{T}];
				 In Vol_The; Integration I1;Jacobian JVol;}		
      Galerkin { [ -qVol[$Time, {T}] , {T} ]; 
                 In Vol_The; Integration I1; Jacobian JVol;  } 
      Galerkin { [ -qSurf[$Time, {T}] , {T} ]; 
                 In Sur_HEATFLUX; Integration I1; Jacobian JSur;  } 
      Galerkin { [ h[{T}] * Dof{T} , {T} ] ; 
                 In Sur_CONVECTIVE ; Integration I1; Jacobian JSur;  } 
      Galerkin { [ -h[{T}] * tref[] , {T} ] ; 
                 In Sur_CONVECTIVE ; Integration I1; Jacobian JSur;  } 
				 
	  Galerkin { [ -qSurf5[$Time, {T}] , {T} ]; 
                 In Sur_CONVECTIVE_HEATFLUX; Integration I1; Jacobian JSur;  } 
      Galerkin { [ h5[{T}] * Dof{T} , {T} ] ; 
                 In Sur_CONVECTIVE_HEATFLUX ; Integration I1; Jacobian JSur;  } 
      Galerkin { [ -h5[{T}] * tref5[] , {T} ] ; 
                 In Sur_CONVECTIVE_HEATFLUX ; Integration I1; Jacobian JSur;  } 
				 
      Galerkin { [ hr[{T}] * sb_constant * (({T}+273.)^4) , {T} ] ; 
                 In Sur_RADIATION ; Integration I1; Jacobian JSur;  } 
				 
	  Galerkin { [ - hr[{T}] * sb_constant * ((trefr[]+273.)^4) , {T} ] ; 
                 In Sur_RADIATION ; Integration I1; Jacobian JSur;  } 
    } 
  } 
}